blob: 5d45c4a4d94af94a0ab00c7a61646f6873217b2f (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
|
# Maintainer: Vitalii Kuzhdin <vitaliikuzhdin@gmail.com>
: "${MAKEPKG_MATLAB_PREFIX:=/opt}"
: "${MAKEPKG_MATLAB_ROOT:=${MAKEPKG_MATLAB_PREFIX}/MATLAB}"
_pkgname="matlab-mcp-core-server"
pkgname="${_pkgname}-git"
pkgver=0.8.0.r0.ge666149
pkgrel=1
pkgdesc="Run MATLAB® using AI applications with the official MATLAB MCP Server from MathWorks®"
arch=(
'x86_64' # glnxa64
)
url="https://www.mathworks.com/products/matlab-mcp-core-server.html"
_url="https://github.com/matlab/${_pkgname}"
license=(
'BSD-3-Clause'
)
depends=(
'glibc'
'matlab-release>=R2020b'
'sh'
)
makedepends=(
'go'
'git'
)
provides=(
"${_pkgname}=${pkgver%.r0.g*}"
)
conflicts=(
"${_pkgname}"
)
_pkgsrc="${_url##*/}"
source=(
"${_pkgsrc}::git+${_url}.git"
# "${_pkgname}_disable_telemetry.patch"
"${_pkgname}.sh"
)
sha256sums=('SKIP'
'49d0f8ed16c0828abccb82839263013eb86b664340f46352021f9374574143e7')
prepare() {
export GOMODCACHE="${srcdir}/go-mod-cache"
cd "${srcdir}/${_pkgsrc}"
# patch -Np1 -i "${srcdir}/${_pkgname}_disable_telemetry.patch" || true
go mod download -modcacherw -x
go mod verify
}
pkgver() {
cd "${srcdir}/${_pkgsrc}"
git describe --long --tags --abbrev=7 | sed 's/v//;s/\([^-]*-g\)/r\1/;s/-/./g'
}
build() {
export CGO_CPPFLAGS="${CPPFLAGS}"
export CGO_CFLAGS="${CFLAGS}"
export CGO_CXXFLAGS="${CXXFLAGS}"
export CGO_LDFLAGS="${LDFLAGS}"
export GOCACHE="${srcdir}/go-cache"
export GOMODCACHE="${srcdir}/go-mod-cache"
export GOFLAGS="-buildmode=pie -trimpath -ldflags=-linkmode=external -mod=readonly -modcacherw"
cd "${srcdir}/${_pkgsrc}"
go build -v -o "build/glnxa64/${_pkgname}" ./"cmd/${_pkgname}"
}
check() {
export MATLAB_MCP_CORE_SERVER_BUILD_DIR="${srcdir}/${_pkgsrc}/build"
export MCP_MATLAB_PATH="$(printf '%s\n' ${MAKEPKG_MATLAB_ROOT}/*/bin | sort -V | tail -n1)"
cd "${srcdir}/${_pkgsrc}"
# go test ./...
go test ./internal/... ./pkg/... ./tests/testutils/... ./tests/integration/...
}
package() {
install -vDm755 "${_pkgname}.sh" "${pkgdir}/usr/bin/${_pkgname}"
cd "${_pkgsrc}"
install -vDm755 "build/glnxa64/${_pkgname}" "${pkgdir}/usr/lib/${_pkgname}/${_pkgname}"
install -vDm644 "README.md" "${pkgdir}/usr/share/doc/${_pkgname}/README.md"
install -vDm644 "LICENSE.md" "${pkgdir}/usr/share/licenses/${_pkgname}/LICENSE.md"
}
|