blob: bb038b53d37523f57bb3d2bc2dae70b831503a61 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
|
# Maintainer: Vitalii Kuzhdin <vitaliikuzhdin@gmail.com>
# https://www.mathworks.com/help/install/ug/get-mpm-os-command-line.html
_name="mpm"
pkgname="matlab-${_name}"
_commit="557baa259149b0f8951d758e4fe971fa7613a77d"
pkgver=2025.3+r135.g557baa2
_pkgver="${pkgver%+*}"
pkgrel=1
epoch=1
pkgdesc="MATLAB Package Manager"
arch=('x86_64')
url="https://www.mathworks.com/products/mpm.html"
_url="https://github.com/mathworks-ref-arch/matlab-dockerfile"
license=('custom:MATLAB EULA')
depends=(
'ca-certificates'
'glibc'
'unzip'
)
makedepends=(
'git'
)
optdepends=(
"${pkgname}-input: input files used with '--inputfile'"
)
_pkgsrc="${_url##*/}"
source=(
"${_pkgsrc}::git+${_url}.git#commit=${_commit}"
)
source_x86_64=(
"${pkgname}-${_pkgver}-x86_64::https://ssd.mathworks.com/supportfiles/downloads/${_name}/${_pkgver}/glnxa64/${_name}"
)
sha256sums=('e79d64be550bedab50dde7fb02cdb58a1a36c41cfd74777bf9d3efd2cd107544')
sha256sums_x86_64=('89a99356a33a6a957d33a655da3c60069fcbdbc16ac1a4bd0da18c076d6027dc')
pkgver() {
cd "${srcdir}/${_pkgsrc}"
printf '%s+r%s.g%s' "${_pkgver}" "$(git rev-list --count HEAD)" "$(git rev-parse --short=7 HEAD)"
}
package() {
cd "${srcdir}"
install -vDm755 "${pkgname}-${_pkgver}-${CARCH}" "${pkgdir}/usr/bin/${pkgname}"
cd "${_pkgsrc}"
install -vDm644 "MPM.md" "${pkgdir}/usr/share/doc/${pkgname}/README.md"
install -vDm644 "LICENSE.md" "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE.md"
ln -vsf "${pkgname}" "${pkgdir}/usr/bin/${_name}"
}
|