blob: 05606e0c0cfd3b1e4942d56025ad8e7ea5998d1a (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
|
# Maintainer: Ivan Shapovalov <intelfx100@gmail.com>
pkgname=matrix-synapse-git
pkgver=0.17.0rc1.r59.g05e3354
pkgrel=1
pkgdesc="Matrix reference homeserver"
license=('Apache')
arch=('any')
url="https://github.com/matrix-org/synapse"
depends=('python2-matrix-angular-sdk-git'
'python2-twisted>=15.1.0' 'python2-service-identity'
'python2-pyopenssl' 'python2-yaml' 'python2-pyasn1' 'python2-pynacl'
'python2-daemonize' 'python2-py-bcrypt' 'python2-frozendict'
'python2-pillow' 'python2-pydenticon' 'python2-ujson' 'python2-blist'
'python2-pysaml2' 'python2-setuptools'
'python2-systemd' 'python2-unpaddedbase64' 'python2-canonicaljson'
'python2-signedjson' 'python2-pymacaroons-pynacl' 'python2-netaddr'
'python2-psutil')
makedepends=('python2-twisted' 'python2-mock' 'python2-setuptools_trial' 'git')
optdepends=('python2-psycopg2: PostgreSQL support (instead of built-in SQLite)')
source=("git://github.com/matrix-org/synapse.git#branch=develop"
'sysusers-synapse.conf'
'deps-relax-pynacl-check.patch'
'deps-relax-pysaml2-check.patch')
md5sums=('SKIP'
'dfbffdd307c5559357a2ff51a1906700'
'a2b653d523161a33a36e931b60a234f2'
'd59b40fc800995f14fedc234ea8031e7')
backup=('etc/synapse/log_config.yaml')
install='synapse.install'
provides=('matrix-synapse')
conflicts=('matrix-synapse')
pkgver() {
cd synapse
git describe --long | sed 's/^v//;s/-rc/rc/;s/-r/./;s/\([^-]*-g\)/r\1/;s/-/./g'
}
prepare() {
cd synapse
git apply -3 "$srcdir/deps-relax-pynacl-check.patch"
git apply -3 "$srcdir/deps-relax-pysaml2-check.patch"
}
build() {
cd synapse
python2 setup.py build
}
package() {
cd synapse
python2 setup.py install --root "${pkgdir}" --optimize=1 --skip-build
for file in "$pkgdir/usr/lib/python2.7/site-packages/synapse"/{app,push}/*.py; do
sed -re 's|env python$|&2.7|' -i "$file"
done
install -Dm644 "contrib/systemd/log_config.yaml" \
"$pkgdir/etc/synapse/log_config.yaml"
install -Dm644 "contrib/systemd/synapse.service" \
"$pkgdir/usr/lib/systemd/system/synapse.service"
install -Dm644 "$srcdir/sysusers-synapse.conf" \
"$pkgdir/usr/lib/sysusers.d/synapse.conf"
}
# vim: set ts=4 sw=4 tw=0 ft=sh :
|