PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60

# Maintainer: Sandwich <sandwich@archworks.co>
pkgname=mautrix-teams
pkgver=28.1
pkgrel=1
pkgdesc="A Matrix-Microsoft Teams puppeting bridge"
arch=('x86_64' 'aarch64')
url="https://github.com/YourSandwich/mautrix-teams"
license=('AGPL-3.0-or-later')
depends=('libolm')
makedepends=('go' 'git')
optdepends=('ffmpeg: voice message and video transcoding')
backup=('etc/mautrix-teams/mautrix-teams.yaml'
        'etc/mautrix-teams/registration.yaml')
install=mautrix-teams.install
source=("$pkgname-$pkgver.tar.gz::$url/archive/refs/tags/v$pkgver.tar.gz"
        'mautrix-teams.service'
        'mautrix-teams.sysusers'
        'mautrix-teams.tmpfiles')
# sha256sums are recomputed by updpkgsums in the Publish AUR workflow before
# the PKGBUILD is pushed to AUR; the committed values are intentionally SKIP.
sha256sums=('2972e3ffa2022337caa539bc3db6972db350dfc9b8bfcac6759bded162cf2bb4'
            'aacb178c68e066e344a66a852fac5ee0bddb4ba5c28d3fe12dd5b3a38926444f'
            '06455386eb56393054ae9b467ebe9d78026d0e92d07e58040e6afd7ffaf0a0ba'
            '17c329e362b7caa7670f063461324db6f625b98043bad82b6c2db7544a37802c')

prepare() {
  cd "$pkgname-$pkgver"
  mkdir -p build
}

build() {
  cd "$pkgname-$pkgver"
  export CGO_CPPFLAGS="${CPPFLAGS}"
  export CGO_CFLAGS="${CFLAGS}"
  export CGO_CXXFLAGS="${CXXFLAGS}"
  export CGO_LDFLAGS="${LDFLAGS}"
  export GOFLAGS="-buildmode=pie -trimpath -mod=readonly -modcacherw"
  ./build.sh -o build/mautrix-teams
}

check() {
  cd "$pkgname-$pkgver"
  go test ./...
}

package() {
  cd "$pkgname-$pkgver"
  install -Dm755 build/mautrix-teams "$pkgdir/usr/bin/mautrix-teams"
  install -Dm644 LICENSE "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
  install -Dm644 LICENSE.exceptions "$pkgdir/usr/share/licenses/$pkgname/LICENSE.exceptions"
  install -Dm644 README.md "$pkgdir/usr/share/doc/$pkgname/README.md"
  install -Dm644 ROADMAP.md "$pkgdir/usr/share/doc/$pkgname/ROADMAP.md"
  install -Dm644 CHANGELOG.md "$pkgdir/usr/share/doc/$pkgname/CHANGELOG.md"

  install -Dm644 "$srcdir/mautrix-teams.service" "$pkgdir/usr/lib/systemd/system/mautrix-teams.service"
  install -Dm644 "$srcdir/mautrix-teams.sysusers" "$pkgdir/usr/lib/sysusers.d/mautrix-teams.conf"
  install -Dm644 "$srcdir/mautrix-teams.tmpfiles" "$pkgdir/usr/lib/tmpfiles.d/mautrix-teams.conf"

  install -dm755 "$pkgdir/etc/mautrix-teams"
}