blob: 534211d1fc736b1f1c06329ea8f0be0b34beff2b (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
|
# Maintainer: William Tang <galaxyking0419@gmail.com>
# Co-Maintainer: Robert Zhou <meep (dot) aur (at) meepzh (dot) com>
pkgname=maya-arnold
pkgver=5.3.5.3
pkgrel=1
pkgdesc='Autodesk Maya Arnold Renderer Plugin'
arch=('x86_64')
url='https://arnoldrenderer.com/download/'
license=('custom')
depends=('maya>=2024' 'maya<2025')
optdepends=('maya-usd: Universal scene description support'
'maya-bifrost: Bifrost effects support')
DLAGENTS+=('manual::/usr/bin/echo \ \ Note: Please download the package manually from Autodesk.com')
source=("manual://MtoA-${pkgver}-linux-2024.run")
b2sums=('661e64f187d569f73062b53c32e6c0521f5215b22b8e7191330a66ab03c45a6aac101715eb20f6fac27af6d38518a3416833eed4df93c9387127f3894dcd29ed')
options=(!strip)
prepare() {
chmod +x ./MtoA-${pkgver}-linux-2024.run
./MtoA-${pkgver}-linux-2024.run --tar xvf
mkdir extracted
echo 'Extracting zip...'
bsdtar -xf *.zip --directory extracted
sed -i 's|any .|any /usr/autodesk/maya2024/plug-ins/arnold|g' extracted/mtoa.mod
}
package() {
mkdir -p "$pkgdir/usr/autodesk/maya2024/"{modules,plug-ins/arnold}
mv extracted/mtoa.mod "$pkgdir/usr/autodesk/maya2024/modules/"
mv extracted/* "$pkgdir/usr/autodesk/maya2024/plug-ins/arnold/"
}
|