blob: e972c6a19c22fe4ec8a8a8dff41ab997ac1dfcfd (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
|
# Maintainer: Maxime Gauduin <alucryd@archlinux.org>
pkgname=maya-calendar-bzr
pkgver=r907
pkgrel=1
pkgdesc='The Pantheon Calendar'
arch=('i686' 'x86_64')
url='https://launchpad.net/maya'
license=('GPL3')
groups=('pantheon-unstable')
depends=('cairo' 'clutter' 'clutter-gtk' 'contractor-bzr'
'evolution-data-server' 'folks' 'gdk-pixbuf2' 'geocode-glib' 'glib2'
'glibc' 'gtk3' 'libchamplain' 'libgee' 'libical' 'libnotify' 'libsoup'
'libgranite.so')
makedepends=('bzr' 'cmake' 'granite-bzr' 'intltool' 'vala')
source=('maya-calendar::bzr+lp:maya')
sha256sums=('SKIP')
pkgver() {
cd maya-calendar
echo "r$(bzr revno)"
}
prepare() {
cd maya-calendar
sed 's|${CMAKE_INSTALL_FULL_LIBDIR}|${CMAKE_INSTALL_PREFIX}/lib|g' -i $(grep -rl CMAKE_INSTALL_FULL_LIBDIR)
}
build() {
cd maya-calendar
if [[ -d build ]]; then
rm -rf build
fi
mkdir build && cd build
cmake .. \
-DCMAKE_BUILD_TYPE='Release' \
-DCMAKE_INSTALL_PREFIX='/usr' \
-DGSETTINGS_COMPILE='FALSE'
make
}
package() {
cd maya-calendar/build
make DESTDIR="${pkgdir}" install
}
# vim: ts=2 sw=2 et:
|