blob: cd7bd1f7f7dcd514b454e7c1f67d26517be293b6 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
|
# Maintainer: Luis Martinez <luis dot martinez at disroot dot org>
pkgname=mazter-git
_pkgname="${pkgname%-git}"
pkgver=r9.b907627
pkgrel=1
pkgdesc='Mazes in your terminal'
arch=('x86_64')
url='https://github.com/canop/mazter'
license=('MIT')
depends=('gcc-libs')
makedepends=('git' 'cargo')
source=("$_pkgname::git+$url")
sha256sums=('SKIP')
pkgver() {
cd "$_pkgname"
(
set -o pipefail
git describe --long --tags 2>/dev/null | sed 's/^v//;s/-/.r/;s/-/./' ||
printf "r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
)
}
prepare() {
cd "$_pkgname"
cargo fetch --locked --target "$CARCH-unknown-linux-gnu"
}
build() {
export RUSTUP_TOOLCHAIN=stable
export CARGO_TARGET_DIR=target
cd "$_pkgname"
cargo build --frozen --release --all-features
}
check() {
export RUSTUP_TOOLCHAIN=stable
cd "$_pkgname"
cargo test --frozen --all-features
}
package() {
cd "$_pkgname"
install -D "target/release/$_pkgname" -t "$pkgdir/usr/bin/"
install -Dm644 LICENSE -t "$pkgdir/usr/share/licenses/$pkgname/"
install -Dm644 README.md -t "$pkgdir/usr/share/doc/$pkgname/"
}
|