PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51

# Maintainer: Chocobo1 <chocobo1 AT archlinux DOT net>
# Former maintainer: Anton Kudryavtsev <boblobl4@gmail.com>

pkgname=mbedtls-git
pkgver=3.4.0.r269.gf740767c0
pkgrel=1
pkgdesc="An open source, portable, easy to use, readable and flexible SSL library"
arch=('i686' 'x86_64')
url="https://www.trustedfirmware.org/projects/mbed-tls/"
license=('Apache')
depends=('glibc')
makedepends=('git' 'perl' 'python-jinja' 'python-jsonschema')
checkdepends=('python')
provides=("mbedtls=$pkgver" 'polarssl' 'libmbedcrypto.so' 'libmbedtls.so' 'libmbedx509.so')
conflicts=('mbedtls' 'polarssl')
options=('staticlibs')
source=("git+https://github.com/Mbed-TLS/mbedtls.git")
sha256sums=('SKIP')


prepare() {
  cd "mbedtls"

  # enable flags for non-embedded systems
  sed -i 's|//\(#define MBEDTLS_THREADING_C\)|\1|' "include/mbedtls/mbedtls_config.h"
  sed -i 's|//\(#define MBEDTLS_THREADING_PTHREAD\)|\1|' "include/mbedtls/mbedtls_config.h"
}

pkgver() {
  cd "mbedtls"

  git describe --long --tags | sed 's/^mbedtls-//;s/^v//;s/\([^-]*-g\)/r\1/;s/-/./g'
}

build() {
  cd "mbedtls"

  make SHARED=1 no_test
}

check() {
  cd "mbedtls"

  make SHARED=1 PYTHON="python" check
}

package() {
  cd "mbedtls"

  make DESTDIR="$pkgdir/usr" install
}