blob: 2f2d6e9b8755a593c6e0ec8959bbd3e3aa43b396 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
|
# Maintainer: Chocobo1 <chocobo1 AT archlinux DOT net>
# Former maintainer: Anton Kudryavtsev <boblobl4@gmail.com>
pkgname=mbedtls-git
pkgver=2.17.0.r258.g75d9a333c
pkgrel=1
pkgdesc="An open source, portable, easy to use, readable and flexible SSL library"
arch=('i686' 'x86_64')
url="https://tls.mbed.org/"
license=('apache')
depends=('glibc')
makedepends=('git')
checkdepends=('python2')
provides=('mbedtls' 'polarssl')
conflicts=('mbedtls' 'polarssl')
options=('staticlibs')
source=("git+https://github.com/ARMmbed/mbedtls.git")
sha256sums=('SKIP')
prepare() {
cd "mbedtls"
# enable flags for non-embedded systems
sed -i 's|//\(#define MBEDTLS_THREADING_C\)|\1|' "include/mbedtls/config.h"
sed -i 's|//\(#define MBEDTLS_THREADING_PTHREAD\)|\1|' "include/mbedtls/config.h"
}
pkgver() {
cd "mbedtls"
git describe --long --tags | sed 's/^mbedtls-//;s/\([^-]*-g\)/r\1/;s/-/./g'
}
build() {
cd "mbedtls"
make SHARED=1 no_test
}
check() {
cd "mbedtls"
make SHARED=1 check
}
package() {
cd "mbedtls"
make DESTDIR="$pkgdir/usr" install
}
|