blob: 358e546524302873e8a1fd27abb0d816140a7f9a (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
|
# Maintainer: peippo <christoph.fink@gmail.com>
pkgname="mbtiles"
pkgdesc="Examine, copy, validate vector tile sets"
url="https://maplibre.org/martin/mbtiles.html"
pkgver=0.15.2
pkgrel=1
_pkgbase=martin
_git_organisation=maplibre
_tag="${pkgname}-v${pkgver}"
arch=("x86_64" "i686")
license=("Apache-2.0 OR MIT")
depends=(
"gcc-libs"
"glibc"
)
makedepends=(
"cargo"
"npm"
)
options=("!lto")
source=(
"${pkgname}-${pkgver}.tar.gz::https://github.com/${_git_organisation}/${_pkgbase}/archive/refs/tags/${_tag}.tar.gz"
"${pkgname}-${pkgver}-LICENSE-APACHE::https://github.com/${_git_organisation}/${_pkgbase}/raw/refs/tags/${_tag}/LICENSE-APACHE"
"${pkgname}-${pkgver}-LICENSE-MIT::https://github.com/${_git_organisation}/${_pkgbase}/raw/refs/tags/${_tag}/LICENSE-MIT"
)
b2sums=(
"66d8abd0b54cf63115e3a2a98d9035776c4b2f259f464e33c5bcdcc7600fd9eacd39864e76856d1dd6a129f991b2191744c26b61812b1205c511dbf394e4fe55"
"cb5ba44d3653218aa76bc8b1d7c1d26b3a72dd35da7490d430a5dda727e9750015c28206d8d7e7c29701dd0c3d24198ff159f2566aff72f9f6edb1f493c0a968"
"fc19c34e958648930a8d8cc56542ffd8eabdea36954d61e9e2f8c6b7f48bef66a61233c5097a5b4f40b79321bfb16b8ef445de0460af115413f7fd3dea825bc9"
)
prepare() {
cd "${srcdir}"/${_pkgbase}-${_tag}
export RUSTUP_TOOLCHAIN=stable
cargo fetch --locked --target "$(rustc -vV | sed -n 's/host: //p')"
}
build() {
cd "${srcdir}"/${_pkgbase}-${_tag}
export RUSTUP_TOOLCHAIN=stable
export CARGO_TARGET_DIR=target
export CFLAGS=
cargo build --frozen --release --all-features --package mbtiles
}
check() {
cd "${srcdir}"/${_pkgbase}-${_tag}
export RUSTUP_TOOLCHAIN=stable
cargo test --frozen --all-features --package mbtiles
}
package() {
cd "${srcdir}"/${_pkgbase}-${_tag}
install -Dm 0755 \
"target/release/mbtiles" \
"${pkgdir}/usr/bin/mbtiles"
cd "${srcdir}"
install -Dm 0644 \
"${pkgname}-${pkgver}-LICENSE-APACHE" \
"${pkgdir}/usr/share/licenses/${pkgname}/LICENSE-APACHE"
install -Dm 0644 \
"${pkgname}-${pkgver}-LICENSE-MIT" \
"${pkgdir}/usr/share/licenses/${pkgname}/LICENSE-MIT"
}
|