blob: ff20598fe2499911f5444e4517b97f25f9ec8afe (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
|
# Maintainer: Pi-Yueh Chuang <pychuang@pm.me>
pkgname=mdpreview-git
pkgver=r79.576dacb
pkgrel=1
pkgdesc="A simple QT-based Markdown previewer, designed to be used with an external editor"
arch=("x86_64")
url="https://github.com/fboender/mdpreview"
license=("GPL3")
depends=("python-pyqt5" "python-markdown" "python-pyinotify" "python-markdown-checklist-git")
makedepends=("git")
provides=("mdpreview")
source=("git+https://github.com/fboender/mdpreview.git")
sha256sums=("SKIP")
# for convenience
_pkgname=mdpreview
pkgver() {
cd "$_pkgname"
printf "r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
}
package() {
# use the original installation script
cd "$_pkgname"
chmod +x ./install.sh
INSTALL_PATH=$pkgdir/usr ./install.sh
# fix link
rm "$pkgdir/usr/bin/mdpreview"
ln -s /usr/lib/mdpreview/mdpreview "$pkgdir/usr/bin"
# install license file
install -Dm644 "LICENSE" -t "$pkgdir/usr/share/licenses/$_pkgname"
}
|