blob: f3ca74267e3fa276522e220f5d7b8c47e2132f48 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
|
# Maintainer: Klaus Alexander Seistrup <klaus@seistrup.dk>
# -*- sh -*-
_pkgname='mdviewer'
pkgname="${_pkgname}-git"
pkgver=0.1.1.r0.g74d3df7
pkgrel=1
pkgdesc='Rendered display of markdown on terminal (built from latest commit)'
arch=('aarch64' 'arm' 'armv6h' 'armv7h' 'i686' 'x86_64')
url='https://github.com/noborus/mdviewer'
license=('MIT') # SPDX-License-Identifier: MIT
provides=("$_pkgname")
conflicts=("$_pkgname")
depends=('glibc')
makedepends=('git' 'go')
source=("git+$url.git")
options=('lto')
sha256sums=('SKIP')
pkgver() {
cd "$_pkgname"
git describe --long --tags | sed 's/^v//;s/-rc\d*//;s/\([^-]*-g\)/r\1/;s/-/./g'
}
prepare() {
cd "$_pkgname"
mkdir -p build
go mod tidy
}
build() {
cd "$_pkgname"
_pkgver=$(git describe --tags --abbrev=0 --always)
_pkgrev=$(git rev-parse --verify --short HEAD)
# RFC-0023
# 🔗 https://rfc.archlinux.page/0023-pack-relative-relocs/
#
# ld(1) says: “Supported for i386 and x86-64.”
case "${CARCH:-unknown}" in
'x86_64' | 'i386' )
export LDFLAGS="$LDFLAGS -Wl,-z,pack-relative-relocs"
;;
* ) : pass ;;
esac
export CGO_CFLAGS="$CFLAGS"
export CGO_CXXFLAGS="$CXXFLAGS"
export CGO_CPPFLAGS="$CPPFLAGS"
export CGO_LDFLAGS="$LDFLAGS"
go build \
-buildmode=pie \
-trimpath \
-ldflags="-linkmode=external -X main.Version=$_pkgver -X main.Revision=$_pkgrev" \
-mod=readonly -modcacherw \
-o build
}
check() {
cd "$_pkgname"
go test
}
package() {
cd "$_pkgname"
install -vDm0755 "build/$_pkgname" "$pkgdir/usr/bin/$_pkgname"
install -vDm0644 README.md "$pkgdir/usr/share/doc/$pkgname/README.md"
install -vDm0644 LICENSE "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
}
# eof
|