summarylogtreecommitdiffstats
path: root/PKGBUILD
blob: 4402e4960ac82c1e8da51ffb4e38bd91b25bdcf8 (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
# Maintainer: Chocobo1 <chocobo1 AT archlinux DOT net>

pkgname=mediainfo-git
pkgver=18.05.r14.g78c2ab41
pkgrel=2
pkgdesc="Utility for displaying technical and tag data for media files"
arch=('i686' 'x86_64')
url="https://mediaarea.net/en/MediaInfo"
license=('BSD')
depends=('glibc' 'libmediainfo')
makedepends=('git')
provides=('mediainfo')
conflicts=('mediainfo')
source=("git+https://github.com/MediaArea/MediaInfo.git")
sha256sums=('SKIP')


pkgver() {
  cd "MediaInfo"

  git describe --long --tags | sed 's/^v//;s/\([^-]*-g\)/r\1/;s/-/./g'
}

build() {
  cd "MediaInfo/Project/GNU/CLI"

  ./autogen.sh
  ./configure --prefix="/usr"
  make
}

package() {
  cd "MediaInfo"

  pushd "Project/GNU/CLI"
  make DESTDIR="$pkgdir" install

  popd
  install -Dm644 "LICENSE" "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
}