blob: 0f9d7c6ff6b77b6b11f7fec8532d73b514536297 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
|
# Maintainer: Rafał Kozdrój <kozeid2@gmail.com>
# Contributor: kikadf <kikadf.01@gmail.com>
# Contributor: Daniel Henry <d at hackr dot pl>
# Contributor: Miguel Revilla <yo at miguelrevilla dot com>
# Contributor: Alfonso Saavedra "Son Link" <sonlink.dourden@gmail.com>
# Contributor: Hexchain Tong <i at hexchain dot org>
pkgname=megasync
_extname=Linux
pkgver=3.7.1.0
pkgrel=1
pkgdesc="Sync your files to your Mega account. Official app"
arch=('i686' 'x86_64')
url="https://github.com/meganz/MEGAsync"
license=('custom:MEGA LIMITED CODE REVIEW LICENCE')
depends=('c-ares' 'crypto++' 'libsodium' 'hicolor-icon-theme' 'libuv' 'qt5-svg' 'libmediainfo')
makedepends=('qt5-tools' 'swig' 'doxygen' 'lsb-release' 'git')
optdepends=('sni-qt: fix systray issue on KDE and LXQt')
source=("git+https://github.com/meganz/MEGAsync.git#tag=v${pkgver}_${_extname}"
"git+https://github.com/meganz/sdk.git")
sha256sums=('SKIP'
'SKIP')
prepare(){
cd "MEGAsync"
git submodule init
git config submodule.src/MEGASync/mega.url $srcdir/sdk
git submodule update
}
build(){
cd "MEGAsync/src/MEGASync/mega"
./autogen.sh
./configure \
--prefix=/usr \
--disable-examples \
--disable-java \
--disable-php \
--disable-python \
--enable-chat \
--with-cares \
--with-cryptopp \
--with-curl \
--with-sodium \
--with-sqlite \
--with-zlib \
--without-freeimage \
--without-termcap \
--without-ffmpeg
cd "../.."
qmake-qt5 CONFIG+="release" MEGA.pro
lrelease-qt5 MEGASync/MEGASync.pro
make
}
package (){
cd "MEGAsync"
install -Dm 644 LICENCE.md "${pkgdir}/usr/share/licenses/megasync/LICENCE"
install -Dm 644 installer/terms.txt "${pkgdir}/usr/share/licenses/megasync/terms.txt"
cd "src"
make INSTALL_ROOT="${pkgdir}" install
cd "MEGASync"
install -Dm 755 megasync "${pkgdir}/usr/bin/megasync"
}
|