blob: 308175438c9bd464c6882e80a02fad66831661bb (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
|
#!/hint/bash
# Maintainer : bartus <arch-local-repo(at).bartus.33mail.com>
# Contributor : Rafał Kozdrój <kozeid2+aur@gmail.com>
# Contributor : kikadf <kikadf.01@gmail.com>
# Contributor : Daniel Henry <d at hackr dot pl>
# Contributor : Miguel Revilla <yo at miguelrevilla dot com>
# Contributor : Alfonso Saavedra "Son Link" <sonlink.dourden@gmail.com>
# Contributor : Hexchain Tong <i at hexchain dot org>
# shellcheck disable=SC2034,SC2154 # unused/uninitialized variables
# shellcheck disable=SC2164 # cd safe
pkgname=megasync-nopdfium
pkgver=4.3.1.0
pkgrel=2
pkgdesc="Easy automated syncing between your computers and your MEGA cloud drive(stripped of pdfium dependency)"
arch=('i686' 'x86_64')
provides=(megasync)
conflicts=(megasync)
url="https://github.com/meganz/MEGAsync"
license=('custom:MEGA LIMITED CODE REVIEW LICENCE')
depends=('c-ares' 'crypto++' 'libsodium' 'hicolor-icon-theme' 'libuv'
'qt5-svg' 'libmediainfo' 'libraw' 'qt5-base' 'ffmpeg')
makedepends=('qt5-tools' 'swig' 'doxygen' 'lsb-release' 'git')
_extname="_Linux"
source=("git+https://github.com/meganz/MEGAsync.git#tag=v${pkgver}${_extname}"
"meganz-sdk::git+https://github.com/meganz/sdk.git"
"qt5_5.15.patch"
)
sha256sums=('SKIP'
'SKIP'
'27cf5f69ed40ae02e2a4145ccb4931834a60c32d907b083e8b3db626c3062562')
prepare() {
cd "MEGAsync"
git submodule init
git config submodule.src/MEGASync/mega.url "../meganz-sdk"
git submodule update
cd "src/MEGASync"
sed -i '/DEFINES += REQUIRE_HAVE_PDFIUM/d' MEGASync.pro
sed -i '/CONFIG += USE_PDFIUM/d' MEGASync.pro
git -C "$srcdir"/MEGAsync apply "$srcdir"/qt5_5.15.patch
}
build() {
# build sdk
cd "MEGAsync/src/MEGASync/mega"
./autogen.sh
./configure \
--disable-shared \
--enable-static \
--disable-silent-rules \
--disable-curl-checks \
--disable-megaapi \
--with-cryptopp \
--with-sodium \
--with-zlib \
--with-sqlite \
--with-cares \
--with-curl \
--without-freeimage \
--with-libuv \
--disable-posix-threads \
--disable-examples \
--with-libzen \
--with-libmediainfo \
--prefix="${srcdir}/MEGAsync/src/MEGASync/mega/bindings/qt/3rdparty"
# build megasync
cd "../.."
qmake-qt5 "CONFIG += FULLREQUIREMENTS" MEGA.pro
lrelease-qt5 MEGASync/MEGASync.pro
make
}
package () {
cd "MEGAsync"
install -Dm 644 LICENCE.md "${pkgdir}/usr/share/licenses/megasync/LICENCE"
install -Dm 644 installer/terms.txt "${pkgdir}/usr/share/licenses/megasync/terms.txt"
install -Dm 644 src/MEGASync/mega/LICENSE "${pkgdir}/usr/share/licenses/megasync/SDK-LICENCE"
cd "src"
install -dm 755 "${pkgdir}/usr/bin"
make INSTALL_ROOT="${pkgdir}" TARGET="${pkgdir}/usr/bin/megasync" install
install -Dm 755 "MEGASync/megasync" "${pkgdir}/usr/bin/megasync"
}
|