PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69


# Maintainer: Bumblebee-3

pkgbase=memoria
pkgname=(memoria-daemon memoria-ui)
pkgver=1.1.0
pkgrel=5
pkgdesc="Clipboard manager with daemon and Qt UI"
arch=('x86_64')
url="https://github.com/Bumblebee-3/memoria"
license=('MIT')

makedepends=(
  cargo
  cmake
  ninja
  wl-clipboard
)

source=("$pkgbase-$pkgver.tar.gz::$url/archive/v$pkgver.tar.gz")
sha256sums=('bf2aabe3e9390551321be3ddf19552407caab185dcf61cff99af8d7ad81c1bc3')

build() {
  cd "$srcdir/$pkgbase-$pkgver"

  # Build daemon
  cargo build --release --locked \
    --manifest-path memoria-daemon/Cargo.toml

  # Build UI
  cmake -S memoria-ui -B build-ui \
    -G Ninja \
    -DCMAKE_BUILD_TYPE=Release \
    -DCMAKE_INSTALL_PREFIX=/usr
  cmake --build build-ui
}

package_memoria-daemon() {
  pkgdesc="Memoria clipboard daemon (systemd user service)"
  depends=(
    gcc-libs
    sqlite
    wl-clipboard
  )

  cd "$srcdir/$pkgbase-$pkgver"

  install -Dm755 \
    memoria-daemon/target/release/memoria-daemon \
    "$pkgdir/usr/bin/memoria-daemon"

  install -Dm644 \
    memoria-daemon/memoria-daemon.service \
    "$pkgdir/usr/lib/systemd/user/memoria-daemon.service"
}

package_memoria-ui() {
  pkgdesc="Memoria Qt6 user interface"
  depends=(
    gcc-libs
    qt6-base
    qt6-declarative
    wl-clipboard
    memoria-daemon
  )

  cd "$srcdir/$pkgbase-$pkgver"
  DESTDIR="$pkgdir" cmake --install build-ui
}