1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
|
# Maintainer: Lone_Wolf <lone_wolf@klaas-de-kat.nl>
# Contributor: Vincent Grande <shoober420@gmail.com>
# Contributor: Armin K. <krejzi at email dot com>
# Contributor: Kristian Klausen <klausenbusk@hotmail.com>
# Contributor: Egon Ashrafinia <e.ashrafinia@gmail.com>
# Contributor: Tavian Barnes <tavianator@gmail.com>
# Contributor: Jan de Groot <jgc@archlinux.org>
# Contributor: Andreas Radke <andyrtr@archlinux.org>
# Contributor: Thomas Dziedzic < gostrc at gmail >
# Contributor: Antti "Tera" Oja <antti.bofh@gmail.com>
# Contributor: Diego Jose <diegoxter1006@gmail.com>
pkgname=mesa-minimal-git
pkgdesc="an open-source implementation of the OpenGL specification, stripped down git version"
pkgver=22.2.0_devel.153079.6ba55b40334
pkgrel=1
arch=('x86_64')
makedepends=('git' 'python-mako' 'xorgproto' 'libxml2' 'libx11' 'libvdpau' 'libva' 'elfutils' 'libxrandr'
'wayland-protocols' 'meson' 'ninja' 'glslang' 'llvm-minimal-git' 'libdrm' 'libclc')
# In order to keep the package simple and ease troubleshooting only use one llvm implementation
optdepends=('opengl-man-pages: for the OpenGL API man pages')
provides=('mesa' 'vulkan-intel' 'vulkan-radeon' 'vulkan-mesa-layer' 'libva-mesa-driver' 'vulkan-swrast' 'vulkan-driver' 'opengl-driver' 'opencl-mesa' 'opencl-driver')
conflicts=('mesa' 'opencl-mesa' 'vulkan-intel' 'vulkan-radeon' 'vulkan-mesa-layer' 'libva-mesa-driver' 'vulkan-swrast' 'mesa-vdpau')
# mixing components from different mesa versions is a bad idea, conflict with everything unique provided by extra/mesa
url="https://www.mesa3d.org"
license=('custom')
source=('mesa::git+https://gitlab.freedesktop.org/mesa/mesa.git'
'LICENSE'
'workaround--LLVM15-FTBFS-no-more-Coroutines.h.patch'
'gallium-clover: LLVM setLangDefaults moved from clangFrontend to clangBasic.patch'
)
md5sums=('SKIP'
'5c65a0fe315dd347e09b1f2826a1df5a'
'a4e1e8a8a90b6434b80d8ec859747e0c'
'c89665c4dd4e98ab9447cb3df371ef1c')
sha512sums=('SKIP'
'25da77914dded10c1f432ebcbf29941124138824ceecaf1367b3deedafaecabc082d463abcfa3d15abff59f177491472b505bcb5ba0c4a51bb6b93b4721a23c2'
'ee96c9c3c29cfd7bffc1ee72fecf6bdd9a4ac7245afa11e7b28432e8695fc9d16d241cb8330029e5460cc54898258b87bc73d99fc1bf9743ce9bb718a85f5806'
'40af0496e6829ecf820104e5f241dfe06cd62479dceb591668e325c6a2fb9fd95b5c60971038de40ebd84d864988e1ae44fa1b743fbecb73d60479d1541937b4')
# ninja grabs all available cores and leaves almost nothing for other processes.
# this package uses the environment variable NINJAFLAGS to allow the user to change this behaviour
# The responsibility to validate the value of NINJAFLAGS lies with the user.
# If unsure, use NINJAFLAGS=""
pkgver() {
cd mesa
read -r _ver <VERSION
echo ${_ver/-/_}.$(git rev-list --count HEAD).$(git rev-parse --short HEAD)
}
prepare() {
# although removing _build folder in build() function feels more natural,
# that interferes with the spirit of makepkg --noextract
if [ -d _build ]; then
rm -rf _build
fi
# see https://gitlab.freedesktop.org/mesa/mesa/-/issues/6359
patch --directory="mesa" --forward --strip=1 --input="${srcdir}/workaround--LLVM15-FTBFS-no-more-Coroutines.h.patch"
# see https://gitlab.freedesktop.org/mesa/mesa/-/issues/6333
patch --directory="mesa" --forward --strip=1 --input="${srcdir}/gallium-clover: LLVM setLangDefaults moved from clangFrontend to clangBasic.patch"
}
build () {
meson setup mesa _build \
-D b_ndebug=true \
-D b_lto=true \
-D buildtype=plain \
--wrap-mode=nofallback \
-D prefix=/usr \
-D sysconfdir=/etc \
-D platforms=x11,wayland \
-D dri-drivers=[] \
-D gallium-drivers=radeonsi,swrast,iris,zink \
-D vulkan-drivers=amd,intel,swrast \
-D dri3=enabled \
-D egl=enabled \
-D gallium-extra-hud=true \
-D gallium-nine=false \
-D gallium-omx=disabled \
-D gallium-va=enabled \
-D gallium-vdpau=disabled \
-D gallium-xa=disabled \
-D gallium-xvmc=disabled \
-D gbm=enabled \
-D gles1=disabled \
-D gles2=enabled \
-D glvnd=true \
-D glx=dri \
-D libunwind=enabled \
-D llvm=enabled \
-D lmsensors=enabled \
-D osmesa=false \
-D shared-glapi=enabled \
-D gallium-opencl=icd \
-D valgrind=disabled \
-D vulkan-layers=device-select,overlay \
-D tools=[] \
-D zstd=enabled \
-D microsoft-clc=disabled \
-D video-codecs=vc1dec,h264dec,h264enc,h265dec,h265enc
meson configure _build
# ninja -j1 -C _build
ninja $NINJAFLAGS -C _build
}
package() {
depends=('libdrm' 'libxxf86vm' 'libxdamage' 'libxshmfence' 'libelf'
'libunwind' 'libglvnd' 'wayland' 'lm_sensors' 'vulkan-icd-loader' 'zstd' 'llvm-libs-minimal-git' 'libclc')
DESTDIR="${pkgdir}" ninja $NINJAFLAGS -C _build install
# remove script file from /usr/bin
# https://gitlab.freedesktop.org/mesa/mesa/issues/2230
rm "${pkgdir}/usr/bin/mesa-overlay-control.py"
rmdir "${pkgdir}/usr/bin"
# indirect rendering
ln -s /usr/lib/libGLX_mesa.so.0 "${pkgdir}/usr/lib/libGLX_indirect.so.0"
install -m644 -Dt "${pkgdir}/usr/share/licenses/${pkgname}" "${srcdir}/LICENSE"
}
|