summarylogtreecommitdiffstats
path: root/PKGBUILD
blob: f4f6517a1258bfadc965fd0a4e2ae3f603b5b0ee (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
# Maintainer: Tony Lambiris <tony@criticalstack.com>

pkgname=mesen-git
_pkgname=Mesen
pkgver=0.9.7.r252.g278ca034
pkgrel=1
pkgdesc='A cross-platform NES/Famicom emulator'
arch=('x86_64')
makedepends=('clang' 'gendesk' 'zip')
depends=('mono' 'sdl2')
conflicts=('mesen')
provides=('mesen')
license=('GPL3')
source=("${_pkgname}::git+https://github.com/SourMesen/Mesen.git")
sha256sums=('SKIP')

pkgver() {
	cd "${srcdir}/${_pkgname}"

	git describe --long --tags | sed 's/\([^-]*-g\)/r\1/;s/-/./g'
}

prepare() {
	cd "${srcdir}/${_pkgname}"

	# Prevent duplicate .desktop from getting created
	sed -i 's/CreateShortcutFile(desktopFile, mimeTypes);//' GUI.NET/Config/FileAssociationHelper.cs

	gendesk --pkgname "${_pkgname}" --pkgdesc "${pkgdesc}" --exec "/usr/bin/mesen" -n

	# Invoke using mono in a wrapper, since wine (if installed) would open it otherwise
	cat > "${pkgname}" <<-EOT
	#!/bin/sh
	/usr/bin/mono /opt/Mesen/Mesen "\$@"
	EOT
}

build() {
	cd "${srcdir}/${_pkgname}"

	mkdir -p bin
	make
}

package() {
	cd "${srcdir}/${_pkgname}"

	install -Dm755 "${pkgname}" "${pkgdir}/usr/bin/${pkgname%%-git}"
	install -Dm644 "${_pkgname}.desktop" "${pkgdir}/usr/share/applications/${_pkgname}.desktop"

	cd "${srcdir}/${_pkgname}/GUI.NET/Resources"
	install -Dm644 "${_pkgname}Icon.png" "${pkgdir}/usr/share/pixmaps/${_pkgname}.png"

	cd "${srcdir}/${_pkgname}/bin/x64/Release"
	install -Dm755 "${_pkgname}.exe" "${pkgdir}/opt/${_pkgname}/${_pkgname}"

	cd "${srcdir}/${_pkgname}/InteropDLL/obj.x64"
	install -Dm644 "lib${_pkgname}Core.x64.dll" "${pkgdir}/usr/lib/lib${_pkgname}Core.dll"
}