blob: 93a87fb0cf07c5ca10e862decc786a688191e9fd (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
|
# Maintainer: Echo J. <aidas957 at gmail dot com>
# shellcheck shell=bash disable=SC2034,SC2164
# A modified version of the meson package (https://gitlab.archlinux.org/archlinux/packaging/packages/meson)
_pkgname=meson
pkgname=meson-rust
pkgver=1.3.0
pkgrel=1
pkgdesc="High productivity build system (version with improved Rust support)"
url="https://mesonbuild.com/"
arch=(any)
license=(Apache)
depends=(
ninja
python-tqdm
python-typing_extensions
)
makedepends=(
python-build
python-installer
python-setuptools
python-wheel
)
provides=("meson=$pkgver")
conflicts=(meson)
source=(
https://github.com/mesonbuild/meson/releases/download/"$pkgver"/meson-"$pkgver".tar.gz{,.asc}
"meson-reference-$pkgver.3::https://github.com/mesonbuild/meson/releases/download/$pkgver/meson-reference.3"
"meson-reference-$pkgver.json::https://github.com/mesonbuild/meson/releases/download/$pkgver/reference_manual.json"
arch-meson
cross-lib32
native-clang
)
b2sums=('cb9ac8e00fe924df67166938687584a9de35e784e1e52bff281649d787695d37e3044ea3d6d5869181fe1e9676b5136548293dbd5cdbd091a6de0c449b8932f5'
'SKIP'
'553cdd8e165593a50570777f0e862a8e20d15dc5b7262c32ca8c86c54c8f2ee1b759be3439e9eec5917c88b3275d755b4f072e979dab400edf18908cb9fbf68e'
'f50c3569c6330e8671c402953247fb456505dd75555c8fbf1487bd43881dcdc766d88348814a6c2bb631c571ad4c4efabb271b5a1e7f01748ae2d9a332b39330'
'211cee61f117fd1d582d7a613a8634f044e9e307791c4154c6da72bccd5f06856801b14bcb26157ee682b5935c48ffd2098a5fabab2232726d7758cf091c07f7'
'9b16477aa77a706492e26fb3ad42e90674b8f0dfe657dd3bd9ba044f921be12ceabeb0050a50a15caee4d999e1ec33ed857bd3bed9e4444d73bb4a4f06381081'
'7d88929d5a3b49d91c5c9969f19d9b47f3151706526b889515acaeda0141257d5115875ac84832e9ea46f83a7700d673adcc5db84b331cd798c70ae6e90eac1e')
validpgpkeys=(
19E2D6D9B46D8DAA6288F877C24E631BABB1FE70 # Jussi Pakkanen <jpakkane@gmail.com>
)
build() {
cd ${_pkgname}-${pkgver}
python -m build --wheel --no-isolation
}
package() {
cd ${_pkgname}-${pkgver}
python -m installer --destdir="$pkgdir" dist/*.whl
install -d "$pkgdir/usr/share/vim/vimfiles"
cp -rt "$pkgdir/usr/share/vim/vimfiles" data/syntax-highlighting/vim/*/
install -Dm644 data/shell-completions/bash/* -t "$pkgdir/usr/share/bash-completion/completions"
install -Dm644 data/shell-completions/zsh/* -t "$pkgdir/usr/share/zsh/site-functions"
install -Dm644 ../meson-reference-$pkgver.3 "$pkgdir/usr/share/man/man3/meson-reference.3"
install -Dm644 ../meson-reference-$pkgver.json "$pkgdir/usr/share/doc/$pkgname/reference_manual.json"
install -D ../arch-meson -t "$pkgdir/usr/bin"
install -Dm644 ../cross-lib32 "$pkgdir/usr/share/meson/cross/lib32"
install -Dm644 ../native-clang "$pkgdir/usr/share/meson/native/clang"
}
# vim:set sw=2 sts=-1 et:
|