PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34

# Maintainer: Ondrej Patrovic <ondrej@patrovic.com>
# Contributor: Marcin Wieczorek <marcin@marcin.co>

_pkgname=messengerfordesktop
pkgname=${_pkgname}-bin
pkgver=2.0.1
pkgrel=2
pkgdesc="Beautiful desktop client for Facebook Messenger. Binary version."
arch=('i686' 'x86_64')
url="http://messengerfordesktop.com/"
license=('MIT')
conflicts=('messengerfordesktop' 'messengerfordesktop-git')
options=(!strip)
depends=('libxtst' 'alsa-lib' 'gtk2' 'gconf' 'libnotify' 'nss')
makedepends=('tar')

_debname="${_pkgname}-${pkgver}.deb"
noextract=("${_debname}")

source_i686=("${_debname}::https://github.com/Aluxian/Facebook-Messenger-Desktop/releases/download/v${pkgver}/${_pkgname}-${pkgver}-linux-i386.deb")
source_x86_64=("${_debname}::https://github.com/Aluxian/Facebook-Messenger-Desktop/releases/download/v${pkgver}/${_pkgname}-${pkgver}-linux-amd64.deb")

sha256sums_i686=('ed05f1afb3d25589c071276c7cc12bff1f5a6e4acb301eeab1cc3300a97d5726')
sha256sums_x86_64=('d4c9eebc60f51c2ba5c136617f6dd71121feb3d8c99b7b563498109d7be74d45')

package() {
	ar p "${_debname}" data.tar.gz | tar -zxpC "${pkgdir}"

	cd "${pkgdir}"
	# Fix the window class in desktop file
	sed -i "s/\(StartupWMClass\).\+/\1=messenger for desktop/" "usr/share/applications/${_pkgname}.desktop"

	install -Dm 644 "opt/${_pkgname}/LICENSE" "usr/share/licenses/${pkgname}/LICENSE"
}