PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63

# Maintainer: Alexander Mot <alexander@amot.dev>
pkgname=metaelite-proton
pkgver=1.02
pkgrel=1
epoch=
pkgdesc="Role playing environment for stories in Elite Dangerous. Runs in ED's Proton-GE prefix"
arch=('any')
url="https://raxxla.org"
license=('custom')
groups=()
depends=('protontricks' 'proton-ge-custom')
makedepends=('msitools' 'icoutils')
checkdepends=()
optdepends=()
provides=('metaelite')
conflicts=()
replaces=()
backup=()
options=()
install=metaelite-proton.install
changelog=
source=("https://cdn.raxxla.org/install/MetaElite-${pkgver}.msi"
        "metaelite-proton"
		"metaelite-proton.desktop")
md5sums=('312d80d06abc0a95f56baa69d43d87d5'
         'afe5965bc05c378cf362ff515d287203'
         'e039e8c693ba247fb0bd2186d4ad5831')
noextract=()
validpgpkeys=()

package() {
    # Extract MSI
    msiextract "MetaElite-${pkgver}.msi" -C "$srcdir"

    # Install binaries
    install -d "${pkgdir}/opt/${pkgname}"
    cp -r "${srcdir}/raxxla.org/MetaElite/"* "${pkgdir}/opt/${pkgname}/"

    # Rename exe and its matching cfg to be version-agnostic
    mv "$pkgdir/opt/$pkgname/MetaElite-${pkgver}.exe" "$pkgdir/opt/$pkgname/MetaElite.exe"
    mv "$pkgdir/opt/$pkgname/app/MetaElite-${pkgver}.cfg" "$pkgdir/opt/$pkgname/app/MetaElite.cfg"

    # Install wrapper script
    install -Dm755 "${srcdir}/${pkgname}" "${pkgdir}/opt/${pkgname}/${pkgname}"

    # Install desktop file
    install -Dm644 "${srcdir}/${pkgname}.desktop" "${pkgdir}/usr/share/applications/${pkgname}.desktop"

    # Create icons
    mkdir -p icons
    msg2 "Extracting icons..."
    wrestool -x -t 14 "${pkgdir}/opt/${pkgname}/MetaElite.exe" -o metaelite.ico                                                                 
    icotool -x metaelite.ico -o icons/

    # Install icons (auto-detect valid sizes)
    cd icons
    for icon in *.png; do
        res=$(echo "$icon" | cut -d'_' -f3 | cut -d'x' -f1)
        if [[ "$res" =~ ^(16|24|32|48|64|96|128|256)$ ]]; then
            install -Dm644 "$icon" "${pkgdir}/usr/share/icons/hicolor/${res}x${res}/apps/${pkgname}.png"
        fi
    done
}