blob: 590ed7b87089b72f592215ff45b639da03bd9cc1 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
|
# Maintainer: nycko123 <nycko123 at gmail com>
# Contributor: haawda <stefan-husmann at t-online de>
# All the credits go to:
# Previous Maintainer (27.04.2016 - 15.10.2017): Youngbin Han <sukso96100 at gmail com>
# Previous Contributor: blainester <theblainestory at gmail com>
pkgname=micro-bin
pkgver=2.0.6
pkgrel=3
pkgdesc="A modern and intuitive terminal-based text editor"
arch=('x86_64' 'i686')
url="https://github.com/zyedidia/micro"
license=('MIT')
optdepends=('xclip: Required for copying/pasting text')
conflicts=('micro-git' 'micro' 'micro-nightly-bin')
provides=('micro')
source_x86_64=("https://github.com/zyedidia/micro/releases/download/v${pkgver}/micro-${pkgver}-linux64.tar.gz")
source_i686=("https://github.com/zyedidia/micro/releases/download/v${pkgver}/micro-${pkgver}-linux32.tar.gz")
#Fixed commits before next release
source=("https://raw.githubusercontent.com/zyedidia/micro/0283155305528929e4799616cec0c2ed3bac0362/assets/packaging/micro.1"
"https://raw.githubusercontent.com/zyedidia/micro/51444765f4b225d0658afd1711174642bebab46d/assets/packaging/micro.desktop"
"https://raw.githubusercontent.com/zyedidia/micro/2caff00ce1fb5494bf1d626ec6bd42cd8117edc1/assets/micro-logo-mark.svg")
sha256sums=('4f703d3625588a8494678ab13ad424ac0ac610278186d3a1e4cd132d7057f401'
'41258ce74409536dd04d6f7b1cc0b1b26f953da45fff7f039201e19a4ef2ea43'
'88686fe20569951f401191c0cf232e1d4a915b549137127681b7b1c5a9c30a2b')
sha256sums_x86_64=('af330834fd2f6ce0ab11515f36d07658b8ec0e1959fcaea6f7e29d8ba49d4c87')
sha256sums_i686=('a6db6c6a1dbefec939137b754e88741d47ffd9aa8e8ca3f94088eb6889f72590')
package(){
install -Dm755 "${srcdir}/${pkgname%-*}-${pkgver}/${pkgname%-*}" "${pkgdir}/usr/bin/${pkgname%-*}"
install -Dm644 "${srcdir}/${pkgname%-*}-${pkgver}/LICENSE" "${pkgdir}/usr/share/licenses/${pkgname%-*}/LICENSE"
install -Dm644 "${srcdir}/${pkgname%-*}-${pkgver}/LICENSE-THIRD-PARTY" "${pkgdir}/usr/share/licenses/${pkgname%-*}/LICENSE-THIRD-PARTY"
for _file in "${srcdir}/${pkgname%-*}-${pkgver}/"*.md; do
install -Dm644 "${_file}" "${pkgdir}/usr/share/doc/${pkgname%-*}/$(basename ${_file})"
done
install -Dm644 "${srcdir}/micro.1" "${pkgdir}/usr/share/man/man1/micro.1"
install -Dm644 "${srcdir}/micro.desktop" "${pkgdir}/usr/share/applications/micro.desktop"
install -Dm644 "${srcdir}/micro-logo-mark.svg" "${pkgdir}/usr/share/pixmaps/micro.svg"
}
|