PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65

# Maintainer: jingyu <francismajere@gmail.com>

pkgname=middlesox-git
_pkgname=middlesox
pkgver=0.0.1.r10.g264a281
pkgrel=1
pkgdesc="Scriptable event-driven controller for window managers and compositors"
arch=('x86_64')
url="https://github.com/washanhanzi/middlesox"
license=('MIT')
depends=('gcc-libs' 'glibc' 'wayland')
makedepends=('rust' 'git' 'pkgconf')
provides=("$_pkgname=$pkgver" 'msx')
conflicts=("$_pkgname" 'msx')
source=("$_pkgname::git+$url.git"
        'LICENSE')
sha256sums=('SKIP'
            'b014105d4927d609815c8f2e274d7187f341cc60ab85f06e86e986882b53aaf4')

pkgver() {
    cd "$srcdir/$_pkgname"

    local version
    version="$(awk -F '"' '/^version = / { print $2; exit }' Cargo.toml)"
    printf '%s.r%s.g%s' "$version" "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
}

prepare() {
    cd "$srcdir/$_pkgname"

    export RUSTUP_TOOLCHAIN=stable
    export CARGO_HOME="$srcdir/cargo-home"
    cargo fetch --locked --target "$CARCH-unknown-linux-gnu"
}

build() {
    cd "$srcdir/$_pkgname"

    export RUSTUP_TOOLCHAIN=stable
    export CARGO_HOME="$srcdir/cargo-home"
    export CARGO_TARGET_DIR=target
    cargo build --frozen --release -p middlesox-cli
}

check() {
    cd "$srcdir/$_pkgname"

    export RUSTUP_TOOLCHAIN=stable
    export CARGO_HOME="$srcdir/cargo-home"
    export CARGO_TARGET_DIR=target
    cargo test --frozen --workspace
}

package() {
    cd "$srcdir/$_pkgname"

    install -Dm755 target/release/msx "$pkgdir/usr/bin/msx"
    install -Dm644 "$srcdir/LICENSE" "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
    install -Dm644 README.md "$pkgdir/usr/share/doc/$_pkgname/README.md"
    install -Dm644 doc/architecture.md "$pkgdir/usr/share/doc/$_pkgname/architecture.md"

    install -Dm644 example/config.toml "$pkgdir/usr/share/doc/$_pkgname/examples/config.toml"
    install -Dm644 -t "$pkgdir/usr/share/doc/$_pkgname/examples/scripts" example/scripts/*.rhai
    install -Dm755 -t "$pkgdir/usr/share/doc/$_pkgname/examples/scripts" example/scripts/*.sh
}