summarylogtreecommitdiffstats
path: root/PKGBUILD
blob: 450e0a9e5684eaedc2c35b83b9c9041f7833731e (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
# Maintainer: Maxime Gauduin <alucryd@archlinux.org>

pkgname=midori-granite-bzr
pkgver=r6929
pkgrel=1
pkgdesc='A lightweight, fast, and free web browser'
arch=('i686' 'x86_64')
url='http://midori-browser.org/'
license=('LGPL2.1')
groups=('pantheon-unstable')
depends=('gcr' 'granite-bzr' 'libnotify' 'libxss' 'libzeitgeist' 'webkitgtk'
         'zeitgeist')
makedepends=('bzr' 'cmake' 'intltool' 'librsvg' 'ninja' 'vala')
optdepends=('gst-plugins-base: HTML5 OGG videos support'
            'gst-plugins-good: HTML5 H264 and WebM videos support'
            'gst-libav: HTML5 H264 videos support')
provides=('midori')
conflicts=('midori')
options=('!emptydirs')
install='midori.install'
source=('bzr+lp:midori')
sha256sums=('SKIP')

pkgver() {
  cd midori

  echo "r$(bzr revno)"
}

build() {
  cd midori

  [[ -d build ]] && rm -rf build
  mkdir build && cd build

  cmake .. \
    -DCMAKE_BUILD_TYPE='Release' \
    -DCMAKE_INSTALL_PREFIX='/usr' \
    -DCMAKE_INSTALL_LIBDIR='/usr/lib' \
    -DUSE_GRANITE='TRUE' \
    -DUSE_GTK3='TRUE' \
    -G Ninja
  ninja
}

package() {
  cd midori/build

  DESTDIR="${pkgdir}" ninja install
}

# vim: ts=2 sw=2 et: