blob: e761fde10afa2dfbd7dfcfca1bc7d433ec5d357b (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
|
# Maintainer: Dmytro Meleshko <dmytro.meleshko@gmail.com>
_pkgname=mindustry
pkgname=${_pkgname}-bin
pkgver=96
pkgrel=1
pkgdesc="A sandbox tower defense game written in Java"
arch=("any")
url="https://github.com/Anuken/Mindustry"
license=("GPL3")
depends=("java-runtime=8" "sh" "hicolor-icon-theme")
makedepends=("libicns")
# provides=(${_pkgname})
replaces=(${_pkgname})
conflicts=(${_pkgname})
source=("${pkgname}-${pkgver}.jar::https://github.com/Anuken/Mindustry/releases/download/v${pkgver}/Mindustry.jar"
"${pkgname}.icns::https://github.com/Anuken/Mindustry/raw/master/core/assets/icons/icon.icns"
"${pkgname}.desktop"
"${pkgname}.sh")
sha256sums=('30d1f984c6924af1d22f7317819a42042393488ca53e7ceed509bab74f70304d'
'16fcae782b13a8460e631d265c505f56393acd14700b016904744bd44aa290eb'
'e5fd49ed3456c53e91b834cb388956e3f9ded4e2c880352d36cf9c2246ca0f0b'
'938f5f9f636379402ba0bb9a53345de499f4f3fd50f232b31605129dcf4ea6c9')
noextract=("${pkgname}-${pkgver}.jar")
build() {
icns2png --extract "${pkgname}.icns"
}
package() {
install -Dm755 "${pkgname}.sh" "${pkgdir}/usr/bin/${_pkgname}"
local icon_size; for icon_size in 256 512 1024; do
install -Dm644 "${pkgname}_${icon_size}x${icon_size}x32.png" \
"${pkgdir}/usr/share/icons/hicolor/${icon_size}x${icon_size}/apps/${_pkgname}.png"
done
install -Dm644 "${pkgname}.desktop" "${pkgdir}/usr/share/applications/${_pkgname}.desktop"
install -Dm755 "${pkgname}-${pkgver}.jar" "${pkgdir}/usr/share/java/${_pkgname}/Mindustry.jar"
}
|