blob: db48f06fd4e8c28c05211cb61a2ebd2e9c4932c2 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
|
# Maintainer: Dmytro Meleshko <dmytro.meleshko@gmail.com>
_pkgname=mindustry
pkgname="${_pkgname}-bin"
_build=126
pkgver="6.0_${_build}"
pkgrel=1
epoch=1
pkgdesc="A sandbox tower defense game written in Java"
arch=("any")
url="https://github.com/Anuken/Mindustry"
license=("GPL3")
depends=("java-runtime>=8" "sh" "hicolor-icon-theme")
makedepends=("libicns")
provides=(${_pkgname})
conflicts=(${_pkgname})
source=("${pkgname}-${_build}.jar::https://github.com/Anuken/Mindustry/releases/download/v${_build}/Mindustry.jar"
"${pkgname}.icns::https://github.com/Anuken/Mindustry/raw/v${_build}/core/assets/icons/icon.icns"
"${pkgname}.desktop"
"${pkgname}.sh")
sha256sums=('6e24d7acff693862e0f163eda65f0c77cd5b43fe4490a7feccf6f8668c1c097c'
'16fcae782b13a8460e631d265c505f56393acd14700b016904744bd44aa290eb'
'e5fd49ed3456c53e91b834cb388956e3f9ded4e2c880352d36cf9c2246ca0f0b'
'938f5f9f636379402ba0bb9a53345de499f4f3fd50f232b31605129dcf4ea6c9')
noextract=("${pkgname}-${_build}.jar")
build() {
icns2png --extract "${pkgname}.icns"
}
package() {
install -Dm755 "${pkgname}.sh" "${pkgdir}/usr/bin/${_pkgname}"
local icon_size; for icon_size in 256 512 1024; do
install -Dm644 "${pkgname}_${icon_size}x${icon_size}x32.png" \
"${pkgdir}/usr/share/icons/hicolor/${icon_size}x${icon_size}/apps/${_pkgname}.png"
done
install -Dm644 "${pkgname}.desktop" "${pkgdir}/usr/share/applications/${_pkgname}.desktop"
install -Dm755 "${pkgname}-${_build}.jar" "${pkgdir}/usr/share/java/${_pkgname}/Mindustry.jar"
}
|