blob: c4137becace2cf5092d6cbcadfa8a89c67657cc1 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
|
# Maintainer: TheWhyteWolf <lordwhyte at gmail dot com>
pkgname=minerva-fm
pkgver=0.1.1
pkgrel=1
pkgdesc="Retro video game music radio for your terminal (SPC, VGM, NSF, MOD, and more)"
arch=('x86_64' 'aarch64')
url="https://github.com/TheWhyteWolf/MiNERVA-FM-Term"
license=('MIT' 'LGPL-2.1-or-later' 'GPL-2.0-or-later')
depends=('gcc-libs' 'alsa-lib' 'libopenmpt' 'libsidplayfp')
makedepends=('cargo')
# makepkg's -flto=auto puts GCC LTO bytecode in the vendored C++ static lib,
# which the Rust linker cannot read; Rust-side LTO still applies via Cargo.
options=('!lto' '!debug')
source=("$pkgname-$pkgver.tar.gz::$url/archive/v$pkgver.tar.gz")
# Regenerate after tagging: updpkgsums && makepkg --printsrcinfo > .SRCINFO
sha256sums=('f58c1c1593c4074cf306e25bfc47c35166eca325ca3615d388b4504594392d44')
prepare() {
cd "MiNERVA-FM-Term-$pkgver"
export RUSTUP_TOOLCHAIN=stable
cargo fetch --locked --target "$(rustc -vV | sed -n 's/host: //p')"
}
build() {
cd "MiNERVA-FM-Term-$pkgver"
export RUSTUP_TOOLCHAIN=stable
export CARGO_TARGET_DIR=target
cargo build --frozen --release
}
check() {
cd "MiNERVA-FM-Term-$pkgver"
export RUSTUP_TOOLCHAIN=stable
cargo test --frozen --release
}
package() {
cd "MiNERVA-FM-Term-$pkgver"
install -Dm755 "target/release/$pkgname" "$pkgdir/usr/bin/$pkgname"
install -Dm644 LICENSE "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
install -Dm644 LICENSES/GME-license.txt \
"$pkgdir/usr/share/licenses/$pkgname/GME-license.txt"
install -Dm644 LICENSES/emu2413-LICENSE.txt \
"$pkgdir/usr/share/licenses/$pkgname/emu2413-LICENSE.txt"
install -Dm644 README.md "$pkgdir/usr/share/doc/$pkgname/README.md"
}
|