PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48

# Maintainer: Michael Koloberdin <michael@koloberdin.com>
pkgname=mingw-w64-catch2v3
_gitcommit=4e8d92bf02f7d1c8006a0e7a5ecabd8e62d98502
pkgver=3.6.0
pkgrel=1
pkgdesc="Modern, C++-native, header-only, test framework for unit-tests, TDD and BDD (v3) (mingw-w64)"
arch=('any')
_archs='i686-w64-mingw32 x86_64-w64-mingw32'
options=(!buildflags)
url="https://github.com/catchorg/Catch2/"
license=('Boost')
depends=('mingw-w64-crt')
makedepends=('git' 'mingw-w64-cmake')
source=(${pkgname}::"git+https://github.com/catchorg/Catch2#commit=${_gitcommit}?signed")
sha512sums=('SKIP')
validpgpkeys=(
  E29C46F3B8A7502860793B7DECC9C20E314B2360 # Martin Hořeňovský
  81E70B717FFB27AFDB45F52090BBFF120F9C087B # Jozef Grajciar
)

pkgver() {
  cd ${pkgname}
  git describe --tags --match 'v*' | sed 's/^v//;s/\([^-]*-g\)/r\1/;s/-/./g'
}

build() {
  cd ${pkgname}
  export CFLAGS+=" ${CPPFLAGS}"
  export CXXFLAGS+=" ${CPPFLAGS}"
  for _arch in ${_archs}; do
    ${_arch}-cmake -B "build-${_arch}" \
      -DCMAKE_INSTALL_PREFIX="/usr/${_arch}" \
      -DBUILD_SHARED_LIBS=OFF \
      -DCMAKE_INSTALL_LIBDIR=lib \
      -DCATCH_BUILD_EXAMPLES=OFF \
      -DCATCH_ENABLE_COVERAGE=OFF \
      -DCATCH_ENABLE_WERROR=OFF \
      -DBUILD_TESTING=ON
    cmake --build "build-${_arch}"
  done
}

package() {
  cd ${pkgname}
  for _arch in ${_archs}; do
    DESTDIR="$pkgdir" cmake --install "build-${_arch}"
  done
}