blob: bb8128bb5e5d8b07fcf9d694ba9a165b4300b8ea (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
|
# Maintainer: Karl-Felix Glatzer <karl.glatzer@gmx.de>
# Contributor: Levente Polyak <anthraxx[at]archlinux[dot]org>
# Contributor: Anatol Pomozov <anatol.pomozov@gmail.com>
pkgname=mingw-w64-cmocka
pkgver=1.1.3
pkgrel=1
pkgdesc='Elegant unit testing framework for C with support for mock objects (mingw-w64)'
url='https://cmocka.org/'
arch=('any')
license=('Apache')
depends=('mingw-w64-crt')
makedepends=('mingw-w64-gcc' 'mingw-w64-cmake' 'mingw-w64-wine')
options=(!strip !buildflags staticlibs)
source=(https://cmocka.org/files/1.1/cmocka-${pkgver}.tar.xz{,.asc}
'cmake.patch')
sha512sums=('b1a2ce72234256d653eebf95f8744a34525b9027e1ecf6552e1620c83a4bdda8b5674b748cc5fd14abada1e374829e2e7f0bcab0b1c8d6c3b7d9b7ec474b6ed3'
'SKIP'
'a9f959ca9f489c3ca57e7671e249064c28b45a00df95395ac46ba0cea5bfc8760253a708a470e04e6c1f9a6f5a882b75fbceef7933b8e200da3579b1580cd671')
validpgpkeys=('8DFF53E18F2ABC8D8F3C92237EE0FC4DCC014E3D') # Andreas Schneider <asn@cryptomilk.org>
_architectures="i686-w64-mingw32 x86_64-w64-mingw32"
prepare() {
cd "${srcdir}/cmocka-${pkgver}"
patch -Np1 -i "${srcdir}"/cmake.patch
}
build() {
for _arch in ${_architectures}; do
mkdir -p "${srcdir}"/build-${_arch} && cd "${srcdir}"/build-${_arch}
WINEPATH="/usr/${_arch}/bin" ${_arch}-cmake ../cmocka-${pkgver} \
-DCMAKE_CROSSCOMPILING=TRUE \
-DBUILD_STATIC_LIB=TRUE \
-DWITH_STATIC_LIB=TRUE \
-DBIN_INSTALL_DIR="/usr/${_arch}/bin" \
-DTARGET_SYSTEM_EMULATOR=${_arch}-wine \
-DUNIT_TESTING=ON
make
done
}
check() {
for _arch in ${_architectures}; do
cd "${srcdir}"/build-${_arch}
WINEDEBUG=-all make test
done
}
package() {
for _arch in ${_architectures}; do
cd "${srcdir}"/build-${_arch}
make install DESTDIR="${pkgdir}"
${_arch}-strip --strip-unneeded "${pkgdir}"/usr/${_arch}/bin/*.dll
${_arch}-strip -g "${pkgdir}"/usr/${_arch}/lib/*.a
done
}
# vim: ts=2 sw=2 et:
|