blob: 354e9affa371e0de4ad0fbe86c2b10640183389d (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
|
pkgname=mingw-w64-coin-or-bonmin
pkgver=1.8.9
pkgrel=1
pkgdesc="Experimental open-source C++ code for solving general MINLP problems (mingw-w64)"
arch=('any')
url="https://projects.coin-or.org/Bonmin"
license=('EPL')
groups=('mingw-w64-coin-or')
depends=('mingw-w64-coin-or-cbc' 'mingw-w64-coin-or-ipopt' 'mingw-w64-nauty')
makedepends=('mingw-w64-configure')
options=('staticlibs' '!buildflags' '!strip')
source=("https://github.com/coin-or/Bonmin/archive/refs/tags/releases/${pkgver}.tar.gz")
sha256sums=('8d130430a2776e250e941ee16f51dba301d5f0a00cc288e05f5b985cf1f426cd')
_architectures="i686-w64-mingw32 x86_64-w64-mingw32"
prepare() {
cd "$srcdir/Bonmin-releases-$pkgver"
# see mingw-w64-coin-or-pkg-config
sed -i "s|export PKG_CONFIG_PATH|export PKG_CONFIG_PATH_CUSTOM|g" Bonmin/configure
sed -i "s| PKG_CONFIG_PATH=| PKG_CONFIG_PATH_CUSTOM=|g" Bonmin/configure
}
build() {
cd "$srcdir/Bonmin-releases-$pkgver"
for _arch in ${_architectures}; do
mkdir -p build-${_arch} && pushd build-${_arch}
LIBS="-lssp" ${_arch}-configure \
--with-osi-lib="$(${_arch}-pkg-config --libs osi)" \
--with-osi-incdir="/usr/${_arch}/include/coin/" \
--with-clp-lib="$(${_arch}-pkg-config --libs clp)" \
--with-clp-incdir="/usr/${_arch}/include/coin/" \
--with-cgl-lib="$(${_arch}-pkg-config --libs cgl)" \
--with-cgl-incdir="/usr/${_arch}/include/coin/" \
--with-coinutils-lib="$(${_arch}-pkg-config --libs coinutils)" \
--with-coinutils-incdir="/usr/${_arch}/include/coin/" \
--with-cbc-lib="$(${_arch}-pkg-config --libs cbc)" \
--with-cbc-incdir="/usr/${_arch}/include/coin/" \
--with-ipopt-lib="$(${_arch}-pkg-config --libs ipopt)" \
--with-ipopt-incdir="/usr/${_arch}/include/coin/" \
--with-asl-lib="$(${_arch}-pkg-config --libs coinasl) $(${_arch}-pkg-config --libs ipoptamplinterface)" \
--with-asl-incdir="/usr/${_arch}/include/coin-or/asl" \
lt_cv_deplibs_check_method=pass_all ..
make
popd
done
}
package() {
for _arch in ${_architectures}; do
cd "$srcdir"/Bonmin-releases-$pkgver/build-${_arch}
PKG_CONFIG_PATH_CUSTOM="$pkgdir"/usr/${_arch}/lib/pkgconfig/ \
make DESTDIR="$pkgdir"/ install
rm "$pkgdir"/usr/${_arch}/bin/*.exe
rm -r "$pkgdir"/usr/${_arch}/share
${_arch}-strip --strip-unneeded "$pkgdir"/usr/${_arch}/bin/*.dll
${_arch}-strip -g "$pkgdir"/usr/${_arch}/lib/*.a
done
}
|