blob: a07fc07c237af9413857aca3e3f054e9f9acc6b3 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
|
pkgname=mingw-w64-coin-or-ipopt
pkgver=3.13.0
pkgrel=1
pkgdesc="Interior Point OPTimizer (mingw-w64)"
arch=('any')
url="https://projects.coin-or.org/Ipopt"
license=('EPL')
groups=('mingw-w64-coin-or')
depends=('mingw-w64-lapack' 'mingw-w64-coin-or-coinasl' 'mingw-w64-coin-or-coinmumps')
makedepends=('mingw-w64-configure' 'mingw-w64-wine' 'wget')
options=('staticlibs' '!buildflags' '!strip')
source=("http://www.coin-or.org/download/source/Ipopt/Ipopt-$pkgver.tgz")
sha256sums=('dc392396be28c4a0d49bfab399320cb3f70db5b8f090028a883d826a47744ecf')
_architectures="i686-w64-mingw32 x86_64-w64-mingw32"
prepare () {
cd "$srcdir/Ipopt-releases-$pkgver"
}
build() {
cd "$srcdir/Ipopt-releases-$pkgver"
for _arch in ${_architectures}; do
mkdir -p build-${_arch} && pushd build-${_arch}
${_arch}-configure \
--with-blas-incdir=/usr/${_arch}/include --with-blas-lib="-lblas" \
--with-lapack-incdir=/usr/${_arch}/include --with-lapack-lib="-llapack" \
lt_cv_deplibs_check_method=pass_all --without-hsl --disable-java ..
make
popd
done
}
package() {
for _arch in ${_architectures}; do
cd "$srcdir"/Ipopt-releases-$pkgver/build-${_arch}
make DESTDIR="$pkgdir"/ install
rm -r "$pkgdir"/usr/${_arch}/share
${_arch}-strip --strip-unneeded "$pkgdir"/usr/${_arch}/bin/*.dll
${_arch}-strip -g "$pkgdir"/usr/${_arch}/lib/*.a
# for compatibility
install -d "$pkgdir"/usr/${_arch}/include/coin
cp -r "$pkgdir"/usr/${_arch}/include/coin-or/* "$pkgdir"/usr/${_arch}/include/coin
done
}
|