blob: 64900fe8def8db80058612ca2aaa29b21f45e449 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
|
# Maintainer: pingplug <pingplug@foxmail.com>
_pkgname=dlib
_architectures="i686-w64-mingw32 x86_64-w64-mingw32"
pkgname=mingw-w64-dlib
pkgver=19.14
pkgrel=1
pkgdesc="A general purpose cross-platform C++ library designed using contract programming and modern C++ techniques (mingw-w64)"
arch=('any')
url="http://www.dlib.net"
license=('custom')
depends=('mingw-w64-crt')
optdepends=('mingw-w64-giflib: for GIF support'
'mingw-w64-lapack: for BLAS and LAPACK support'
'mingw-w64-libjpeg: for JPEG support'
'mingw-w64-libpng: for PNG support'
'mingw-w64-sqlite: for sqlite support')
makedepends=('mingw-w64-cmake')
options=('!strip' 'staticlibs' '!buildflags')
source=("https://downloads.sourceforge.net/project/dclib/${_pkgname}/v${pkgver}/${_pkgname}-${pkgver}.tar.bz2")
sha256sums=('b552e2f1c3a4fc3fc5e9a127e3cc3c6c1b0d7bd6eb7d886a5cca1db192def034')
build() {
cd ${srcdir}
for _arch in ${_architectures}; do
# shared
mkdir -p "${_pkgname}-build-${_arch}-shared" && pushd "${_pkgname}-build-${_arch}-shared"
${_arch}-cmake \
-DBUILD_SHARED_LIBS:BOOL=ON \
-DUSE_AVX_INSTRUCTIONS:BOOL=ON \
-DUSE_SSE2_INSTRUCTIONS:BOOL=ON \
-DUSE_SSE4_INSTRUCTIONS:BOOL=ON \
"../${_pkgname}-${pkgver}"
make
popd
# static
mkdir -p "${_pkgname}-build-${_arch}-static" && pushd "${_pkgname}-build-${_arch}-static"
${_arch}-cmake \
-DBUILD_SHARED_LIBS:BOOL=OFF \
-DUSE_AVX_INSTRUCTIONS:BOOL=ON \
-DUSE_SSE2_INSTRUCTIONS:BOOL=ON \
-DUSE_SSE4_INSTRUCTIONS:BOOL=ON \
"../${_pkgname}-${pkgver}"
make
popd
done
}
package() {
cd ${srcdir}
for _arch in ${_architectures}; do
pushd "${_pkgname}-build-${_arch}-shared"
make DESTDIR=${pkgdir} install
popd
mv "${pkgdir}/usr/${_arch}/lib/cmake/dlib/"{dlib,dlib-shared}.cmake
pushd "${_pkgname}-build-${_arch}-static"
make DESTDIR=${pkgdir} install
popd
mv "${pkgdir}/usr/${_arch}/lib/cmake/dlib/"{dlib,dlib-static}.cmake
pushd "${pkgdir}/usr/${_arch}/lib/cmake/dlib/"
ln -s dlib-static.cmake dlib.cmake
popd
${_arch}-strip --strip-unneeded "${pkgdir}/usr/${_arch}/bin/"*.dll
${_arch}-strip -g "${pkgdir}/usr/${_arch}/lib/"*.a
done
install -Dm644 "${_pkgname}-${pkgver}/dlib/LICENSE.txt" "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
}
# vim:set ts=2 sw=2 et:
|