blob: d89812ab748256132ddfaa48bbaf93134b059836 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
|
pkgname=mingw-w64-gdb
pkgver=8.3.1
pkgrel=1
pkgdesc="The GNU Debugger (mingw-w64)"
arch=(any)
url="http://www.gnu.org/software/gdb/"
license=('LGPL')
depends=('mingw-w64-crt' 'mingw-w64-expat' 'mingw-w64-zlib' 'mingw-w64-readline')
makedepends=('mingw-w64-configure' 'texinfo')
options=('staticlibs' '!buildflags' '!strip')
source=("http://ftp.gnu.org/gnu/gdb/gdb-${pkgver}.tar.xz")
sha256sums=('1e55b4d7cdca7b34be12f4ceae651623aa73b2fd640152313f9f66a7149757c4')
_architectures="i686-w64-mingw32 x86_64-w64-mingw32"
build() {
cd "$srcdir/gdb-$pkgver"
for _arch in ${_architectures}; do
mkdir -p build-${_arch} && pushd build-${_arch}
${_arch}-configure \
--enable-lto \
--disable-source-highlight \
--with-system-readline \
--with-expat ..
make
popd
done
}
package() {
for _arch in ${_architectures}; do
cd "$srcdir"/gdb-${pkgver}/build-${_arch}
make install DESTDIR="$pkgdir"
rm -rf "$pkgdir"/usr/${_arch}/share/{man,info,locale}
rm -rf "$pkgdir"/usr/${_arch}/lib
rm -rf "$pkgdir"/usr/${_arch}/include
${_arch}-strip "$pkgdir"/usr/${_arch}/bin/gdb.exe
${_arch}-strip "$pkgdir"/usr/${_arch}/bin/gdbserver.exe
done
}
|