blob: 7c1922258dcb18cbb46ba6820d417849dafb3cce (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
|
# Maintainer: Aleksey Filippov <sarum9in@gmail.com>
# Contributor: xantares <xantares09 at hotmail dot com>
pkgname=mingw-w64-gdbm
pkgver=1.10
pkgrel=2
pkgdesc="GNU database library (mingw-w64)"
url="http://www.gnu.org/software/gdbm/gdbm.html"
license=('GPL')
arch=('any')
depends=('mingw-w64-crt')
makedepends=('mingw-w64-gcc' 'mingw-w64-gettext')
source=("http://ftp.gnu.org/gnu/gdbm/gdbm-${pkgver}.tar.gz"
'gdbm-1.10-zeroheaders.patch'
'gdbm-win32-support.patch')
options=('staticlibs' '!buildflags' '!strip')
md5sums=('88770493c2559dc80b561293e39d3570'
'ac255b10452005237836cd2d3a470733'
'231f5c2a491af140e916ec1bd4825480')
_architectures="i686-w64-mingw32 x86_64-w64-mingw32"
prepare() {
cd "${srcdir}/gdbm-${pkgver}"
# Prevent gdbm from storing uninitialized memory content
# to database files. This patch improves security, as the
# uninitialized memory might contain sensitive informations
# from other applications.
# https://bugzilla.redhat.com/show_bug.cgi?id=4457
# http://bugs.debian.org/cgi-bin/bugreport.cgi?bug=208927
patch -Np1 -i ../gdbm-1.10-zeroheaders.patch
# http://pkgs.fedoraproject.org/cgit/mingw-gdbm.git/tree/gdbm-win32-support.patch
patch -Np0 -i ../gdbm-win32-support.patch
autoreconf -vfi
}
build() {
cd "${srcdir}/gdbm-${pkgver}"
for _arch in ${_architectures}; do
unset LDFLAGS
mkdir -p "build-${_arch}" && pushd "build-${_arch}"
../configure \
--prefix=/usr/${_arch} \
--host=${_arch}
make
popd
done
}
package() {
for _arch in ${_architectures}; do
cd "${srcdir}/gdbm-${pkgver}/build-$_arch"
make DESTDIR="$pkgdir" install
rm -r "$pkgdir"/usr/${_arch}/share
rm "$pkgdir"/usr/${_arch}/bin/*.exe
${_arch}-strip --strip-unneeded "$pkgdir"/usr/${_arch}/bin/*.dll
${_arch}-strip -g "$pkgdir"/usr/${_arch}/lib/*.a
# create symlinks for compatibility
install -dm755 "${pkgdir}"/usr/${_arch}/include/gdbm
ln -sf ../gdbm.h "${pkgdir}"/usr/${_arch}/include/gdbm/gdbm.h
done
}
|