blob: 3d62014b62b9d02f19ba6b9fe83669dafe566b60 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
|
# Contributor: Filip Brcic <brcha@gna.org>
# Contributor: Martchus <martchus@gmx.net>
pkgname=mingw-w64-gettext
pkgver=0.19.8.1
pkgrel=1
arch=('any')
pkgdesc='GNU internationalization library (mingw-w64)'
depends=('mingw-w64-termcap' 'mingw-w64-libunistring')
makedepends=('gettext' 'mingw-w64-configure')
options=(!strip !buildflags staticlibs)
license=("GPL")
url="http://www.gnu.org/software/gettext/"
source=("http://ftp.gnu.org/pub/gnu/gettext/gettext-${pkgver}.tar.gz"{,.sig}
"00-relocatex-libintl-0.18.3.1.patch"
"05-always-use-libintl-vsnprintf.mingw.patch"
"06-dont-include-ctype-after-gnulibs-wctype.mingw.patch"
"07-fix-asprintf-conflict.mingw.patch"
"08-vs-compatible.patch"
"09-gnulib-fix-underscore-cond.patch")
md5sums=('97e034cf8ce5ba73a28ff6c3c0638092'
'SKIP'
'6f43ea4763a0cd461f60c71197832fba'
'27852a388b8cf38188dc392c244230ff'
'f69747f43f279b8a81286cfe5916b82f'
'3ebccf730ec3377b068027eb2283afb2'
'f5b611172ae58f1e4589a8d0c1d53414'
'bed0da63d251975a21ca830f2f156766')
validpgpkeys=('462225C3B46F34879FC8496CD605848ED7E69871') # Daiki Ueno
_architectures='i686-w64-mingw32 x86_64-w64-mingw32'
prepare() {
cd gettext-$pkgver
rm -f gettext-runtime/intl/canonicalize.c
rm -f gettext-runtime/intl/relocatex.{h,c}
rm -f MINGW-PATCHES/README-relocatex-libintl.txt
patch -p1 -i ${srcdir}/00-relocatex-libintl-0.18.3.1.patch
patch -p0 -i ${srcdir}/05-always-use-libintl-vsnprintf.mingw.patch
patch -p0 -i ${srcdir}/06-dont-include-ctype-after-gnulibs-wctype.mingw.patch
patch -p0 -i ${srcdir}/07-fix-asprintf-conflict.mingw.patch
patch -p0 -i ${srcdir}/08-vs-compatible.patch
# prevents "Cannot export rpl_printf: symbol not found"
patch -p0 -i ${srcdir}/09-gnulib-fix-underscore-cond.patch
}
build() {
cd gettext-${pkgver}
unset LDFLAGS
for _arch in ${_architectures}; do
mkdir -p build-${_arch} && pushd build-${_arch}
# define USER_LABEL_PREFIX_UNDERSCORE to prevent undefined reference to `__imp_exit_failure'
# and similar errors
local underscore_flag=''
[[ ${_arch} == i686-w64-mingw32 ]] && underscore_flag='-DUSER_LABEL_PREFIX_UNDERSCORE'
export CFLAGS="$underscore_flag"
export CXXFLAGS="$underscore_flag"
${_arch}-configure \
--disable-java \
--disable-native-java \
--disable-csharp \
--enable-threads=win32 \
--without-emacs ..
make
popd
done
}
package() {
for _arch in ${_architectures}; do
cd "${srcdir}/${pkgname#mingw-w64-}-$pkgver/build-${_arch}"
make DESTDIR="$pkgdir" install
rm "$pkgdir/usr/${_arch}/bin/"{autopoint,gettext.sh,gettextize}
rm -r "$pkgdir/usr/${_arch}/lib/gettext"
rm -r "$pkgdir/usr/${_arch}/share"
rm "$pkgdir"/usr/${_arch}/bin/*.exe
${_arch}-strip --strip-unneeded "$pkgdir"/usr/${_arch}/bin/*.dll
${_arch}-strip -g "$pkgdir"/usr/${_arch}/lib/*.a
done
}
|