blob: de5594fd3300dd0a649c07a2f215dad53051d169 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
|
# Maintainer: drakkan <nicola.murino at gmail dot com>
# Contributor: Filip Brcic <brcha@gna.org>
# Contributor: ant32 <antreimer@gmail.com>
# Contributor: Renato Silva <br.renatosilva@gmail.com>
# Contributor: Martchus <martchus@gmx.net>
pkgname=mingw-w64-glib2
pkgver=2.62.4
pkgrel=1
_commit=dac69d7128b3b66ed7007ab944eb629d30f4de4b # tags/2.62.4^0
arch=(any)
pkgdesc="Low level core library (mingw-w64)"
depends=(mingw-w64-libffi mingw-w64-pcre mingw-w64-gettext mingw-w64-zlib)
makedepends=(mingw-w64-meson git)
license=("LGPL2.1")
options=(!strip !buildflags staticlibs !emptydirs)
url="https://wiki.gnome.org/Projects/GLib"
source=("git+https://gitlab.gnome.org/GNOME/glib.git#commit=$_commit"
"0001-Use-CreateFile-on-Win32-to-make-sure-g_unlink-always.patch"
"glib-prefer-constructors-over-DllMain.patch")
sha256sums=('SKIP'
'1cea1995b0e21268e55ceed04484305418a471a932f268530e48e2d0e08f8e06'
'9698fe428a380e568c3b83035856f83b1c70bf76dc09df7948ddebe7ca39ed65')
_architectures="i686-w64-mingw32 x86_64-w64-mingw32"
pkgver() {
cd glib
git describe --tags | sed 's/-/+/g'
}
prepare() {
cd glib
# https://gitlab.gnome.org/GNOME/glib/issues/539
patch -Np1 -i ../0001-Use-CreateFile-on-Win32-to-make-sure-g_unlink-always.patch
# https://gitlab.gnome.org/GNOME/glib/issues/692
patch -Np1 -i ../glib-prefer-constructors-over-DllMain.patch
}
build() {
for _arch in ${_architectures}; do
mkdir -p "${srcdir}/glib/build-${_arch}"
cd "${srcdir}/glib/build-${_arch}"
${_arch}-meson \
--default-library both ..
ninja
done
}
package() {
for _arch in ${_architectures}; do
# fix pkg-config files (see https://github.com/mesonbuild/meson/pull/3939)
for pc_file in ${srcdir}/glib/build-${_arch}/meson-private/*.pc; do
sed -i 's/-lgnulib//g' "$pc_file"
sed -i 's/-lcharset//g' "$pc_file"
sed -i 's/-lgiowin32//g' "$pc_file"
done
DESTDIR="${pkgdir}" ninja -C "${srcdir}/glib/build-${_arch}" install
done
}
# vim: ts=2 sw=2 et:
|