blob: 0eb9058e842167478b9cae71e44b2e56fbb9bc27 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
|
# Maintainer: drakkan <nicola.murino at gmail dot com>
# Contributor: Filip Brcic <brcha@gna.org>
# Contributor: ant32 <antreimer@gmail.com>
# Contributor: Renato Silva <br.renatosilva@gmail.com>
# Contributor: Martchus <martchus@gmx.net>
pkgname=mingw-w64-glib2
pkgver=2.58.2
pkgrel=1
_commit=97bcbcb8c2aa0aeee5afd9939efbadbae0c8a8fa # tags/2.58.2^0
arch=(any)
pkgdesc="Low level core library (mingw-w64)"
depends=(mingw-w64-libffi mingw-w64-pcre mingw-w64-gettext mingw-w64-zlib)
makedepends=(mingw-w64-meson git)
license=("LGPL2.1")
options=(!strip !buildflags staticlibs !emptydirs)
url="https://wiki.gnome.org/Projects/GLib"
source=("git+https://gitlab.gnome.org/GNOME/glib.git#commit=$_commit"
"0001-Use-CreateFile-on-Win32-to-make-sure-g_unlink-always.patch"
"0001-win32-Make-the-static-build-work-with-MinGW-when-pos.patch")
sha256sums=('SKIP'
'ff0d3df5d57cf621cac79f5bea8bd175e6c18b3fbf7cdd02df38c1eab9f40ac3'
'838abaeab8ca4978770222ef5f88c4b464545dd591b2d532c698caa875b46931')
_architectures="i686-w64-mingw32 x86_64-w64-mingw32"
pkgver() {
cd glib
git describe --tags | sed 's/-/+/g'
}
prepare() {
cd glib
# https://gitlab.gnome.org/GNOME/glib/issues/539
patch -Np1 -i ../0001-Use-CreateFile-on-Win32-to-make-sure-g_unlink-always.patch
# https://gitlab.gnome.org/GNOME/glib/issues/692
patch -Np1 -i ../0001-win32-Make-the-static-build-work-with-MinGW-when-pos.patch
}
build() {
for _arch in ${_architectures}; do
mkdir -p "${srcdir}/glib/build-${_arch}"
cd "${srcdir}/glib/build-${_arch}"
${_arch}-meson \
--default-library both ..
ninja
done
}
package() {
for _arch in ${_architectures}; do
# fix pkg-config files (see https://github.com/mesonbuild/meson/pull/3939)
for pc_file in ${srcdir}/glib/build-${_arch}/meson-private/*.pc; do
sed -i 's/-lgnulib//g' "$pc_file"
sed -i 's/-lcharset//g' "$pc_file"
sed -i 's/-lgiowin32//g' "$pc_file"
done
DESTDIR="${pkgdir}" ninja -C "${srcdir}/glib/build-${_arch}" install
# see https://github.com/mesonbuild/meson/issues/4138
${_arch}-gcc-ranlib ${pkgdir}/usr/${_arch}/lib/*.a
done
}
# vim: ts=2 sw=2 et:
|