blob: 12dfce368b0818c80ffb6660d92c34fc85634975 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
|
# Maintainer: Karl-Felix Glatzer <karl.glatzer@gmx.de>
# Contributor: Maxime Gauduin <alucryd@archlinux.org>
# Contributor: Ray Rashif <schiv@archlinux.org>
# Contributor: Ionut Biru <ibiru@archlinux.org>
# Contributor: Hugo Doria <hugo@archlinux.org>
pkgname=mingw-w64-lame
pkgver=3.101.r6531
pkgrel=1
pkgdesc="A high quality MPEG Audio Layer III (MP3) encoder (mingw-w64)"
arch=('any')
url="http://lame.sourceforge.net/"
depends=(
mingw-w64-crt
mingw-w64-mpg123
mingw-w64-ncurses
)
options=('!strip' '!buildflags' '!libtool' 'staticlibs' '!debug')
makedepends=(
mingw-w64-gcc
mingw-w64-configure
mingw-w64-wine
nasm
subversion)
license=(LGPL-2.0-only)
_revision=6531
source=(
svn+https://svn.code.sf.net/p/lame/svn/trunk/lame#revision=6531
lame-symbols.patch
lame-cbr-abr-quality-settings-clamp.patch
mingw.patch
wine.patch
winsock2.patch
)
b2sums=('SKIP'
'c8cc00f560515231dba1bf9393d056ecb11c2268bafae4923e8c2594b92de473b94e6e5cbef1e52b4843ddd36bb4e06ea6b24ac4a18aa682b2ab7c5ef6deb73c'
'217cf6611f13cb91997856c3af9c30b7c23fa3744126d27f71768001b6799a4a100c9c0baec34beb656fee1c8c519c86b1a9c549e2ea6befe197eb930f70caaa'
'b96dda3836a85106cbe297ea896e9b86741f358764d34149c4f3901477f55bffe4e06a32753b9a183081c3d015ba321a4562572c0a2266e0a9b0b731a9980487'
'aadab9300aa62e35f447464d0e06326f26909375c3ada27ad42c042f62078319c469b59f321e4ef25062de1280012cebba58c683b81ba852a7a8f0136c370ed3'
'6bcc4e4605ad01bb2bc3b62904880e2ae298724769752f0fcf12ed5aef1e501e31bc535c4397dbc0befbbcb895a0f84cf7fc7c074c1a4d95842909d74cc364af')
_architectures="i686-w64-mingw32 x86_64-w64-mingw32"
prepare() {
cd ${srcdir}/lame
patch -Np1 -i "${srcdir}/lame-symbols.patch"
patch -Np1 -i "${srcdir}/lame-cbr-abr-quality-settings-clamp.patch"
patch -Np1 -i "${srcdir}/mingw.patch"
patch -Np1 -i "${srcdir}/wine.patch"
patch -Np1 -i "${srcdir}/winsock2.patch"
}
pkgver() {
echo "3.101.r${_revision}"
}
build() {
for _arch in ${_architectures}; do
mkdir -p ${srcdir}/lame/build-${_arch} && cd ${srcdir}/lame/build-${_arch}
unset LDFLAGS CPPFLAGS
export LIBS="-lncursesw"
export CFLAGS="-msse"
export CFLAGS+=" -Wno-implicit-function-declaration -Wno-incompatible-pointer-types"
export CPPFLAGS="-msse"
${_arch}-configure \
--enable-nasm \
--enable-mp3rtp \
--enable-shared
make
done
}
check() {
for _arch in ${_architectures}; do
WINE=${_arch}-wine make test -C ${srcdir}/lame/build-${_arch}
done
}
package() {
for _arch in ${_architectures}; do
cd ${srcdir}/lame/build-${_arch}
make DESTDIR="$pkgdir" install
${_arch}-strip -s $pkgdir/usr/${_arch}/bin/*.exe
${_arch}-strip -x -g ${pkgdir}/usr/${_arch}/bin/*.dll
${_arch}-strip -g ${pkgdir}/usr/${_arch}/lib/*.a
rm -r $pkgdir/usr/${_arch}/share
chmod 644 ${pkgdir}/usr/${_arch}/lib/*.dll.a
done
}
# vim:set ts=2 sw=2 et:
|