blob: 3c38c239d83fc1e4d0f8e0ba13ff95c4aa313976 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
|
# Maintainer: lantw44 at gmail dot com
pkgname=mingw-w64-libepoxy
pkgver=1.4.2
pkgrel=1
pkgdesc="A library for handling OpenGL function pointer management for you (mingw-w64)"
arch=(any)
url="https://github.com/anholt/libepoxy"
license=('MIT')
makedepends=(
'mingw-w64-gcc'
'mingw-w64-configure'
'python'
'xorg-util-macros')
depends=(
'mingw-w64-crt')
options=(!strip !buildflags staticlibs)
source=("https://github.com/anholt/libepoxy/releases/download/${pkgver}/libepoxy-${pkgver}.tar.xz")
sha256sums=('bea6fdec3d10939954495da898d872ee836b75c35699074cbf02a64fcb80d5b3')
_architectures="i686-w64-mingw32 x86_64-w64-mingw32"
build() {
cd "${srcdir}/libepoxy-${pkgver}"
for _arch in ${_architectures}; do
mkdir -p "build-${_arch}"
cd "build-${_arch}"
${_arch}-configure
make
cd ..
done
}
package() {
cd "${srcdir}/libepoxy-${pkgver}"
for _arch in ${_architectures}; do
cd "build-${_arch}"
make DESTDIR="$pkgdir" install
find "$pkgdir/usr/${_arch}" -name '*.exe' | xargs -rtL1 ${_arch}-strip
find "$pkgdir/usr/${_arch}" -name '*.dll' | xargs -rtL1 ${_arch}-strip --strip-unneeded
find "$pkgdir/usr/${_arch}" -name '*.a' -o -name '*.dll' | xargs -rtL1 ${_arch}-strip -g
cd ..
done
}
|