blob: 9b6ad6af36a21761f8e655767af8e0399a8fd7ed (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
|
# Maintainer: Patrick Northon <northon_patrick3@yahoo.ca>
_pkgname=libheif
pkgname=mingw-w64-${_pkgname}
pkgver=1.16.1
pkgrel=1
pkgdesc='HEIF file format decoder and encoder (mingw-w64)'
url='https://github.com/strukturag/libheif'
license=('LGPL')
depends=(
'mingw-w64-crt'
'mingw-w64-libpng'
'mingw-w64-libjpeg-turbo'
'mingw-w64-aom'
'mingw-w64-x265'
'mingw-w64-libde265'
'mingw-w64-rav1e'
'mingw-w64-dav1d'
'mingw-w64-zlib'
'mingw-w64-svt-av1' # Only for x86_64
)
makedepends=('mingw-w64-cmake')
arch=('any')
options=(!strip !buildflags staticlibs)
optdepends=()
sha256sums=('005e337d60436759af80deaf25c7dcf3a98d976b1c8c30117c830aae3452afe5')
source=(
"$_pkgname-$pkgver.tar.gz::https://github.com/strukturag/libheif/archive/v${pkgver}.tar.gz"
)
_srcdir="${_pkgname}-${pkgver}"
_architectures='i686-w64-mingw32 x86_64-w64-mingw32'
_flags=(
-Wno-dev
-DCMAKE_BUILD_TYPE=Release
-DCMAKE_CXX_FLAGS_RELEASE='-DNDEBUG'
-DCMAKE_CXX_STANDARD_LIBRARIES='-lws2_32 -lwsock32 -luserenv'
-DWITH_RAV1E=OFF
-DWITH_SvtEnc=ON # Only supported on 64 bits platforms
-DWITH_SvtEnc_PLUGIN=OFF
-DWITH_EXAMPLES=OFF
-DWITH_REDUCED_VISIBILITY=ON
-DWITH_DEFLATE_HEADER_COMPRESSION=ON )
build() {
for _arch in ${_architectures}; do
${_arch}-cmake -S "${_srcdir}" -B "build-${_arch}-static" "${_flags[@]}" \
-DBUILD_SHARED_LIBS=OFF \
-DCMAKE_INSTALL_PREFIX="/usr/${_arch}/static"
cmake --build "build-${_arch}-static"
${_arch}-cmake -S "${_srcdir}" -B "build-${_arch}" "${_flags[@]}"
cmake --build "build-${_arch}"
done
}
package() {
for _arch in ${_architectures}; do
DESTDIR="${pkgdir}" cmake --install "build-${_arch}-static"
${_arch}-strip -g "$pkgdir"/usr/${_arch}/static/lib/*.a
DESTDIR="${pkgdir}" cmake --install "build-${_arch}"
${_arch}-strip --strip-unneeded "$pkgdir"/usr/${_arch}/bin/*.dll
${_arch}-strip -g "$pkgdir"/usr/${_arch}/lib/*.a
done
}
|