blob: 5db64096e346ecf48bf8206174ccb9130f496e43 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
|
# Maintainer: Vitalii Kuzhdin <vitaliikuzhdin@gmail.com>
# Contributor: Andrew Sun <adsun701 at gmail dot com>
# Contributor: David Schury <dasc at posteo dot de>
_name="libsigc++"
pkgname="mingw-w64-${_name}"
pkgver=2.12.1
pkgrel=1
epoch=1
pkgdesc="Callback Framework for C++ (mingw-w64)"
arch=('any')
url="https://libsigcplusplus.github.io/libsigcplusplus"
# _url="https://github.com/libsigcplusplus/libsigcplusplus"
license=('LGPL-3.0-or-later')
depends=('mingw-w64-crt')
makedepends=('mingw-w64-meson>=0.55' 'mm-common')
provides=('mingw-w64-libsigc++2.0')
conflicts=('mingw-w64-libsigc++2.0')
replaces=('mingw-w64-libsigc++2.0')
options=('!strip' '!buildflags' 'staticlibs')
_pkgsrc="${_name}-${pkgver}"
source=("${_pkgsrc}.tar.xz::https://download.gnome.org/sources/${_name}/${pkgver%.*}/${_pkgsrc}.tar.xz")
sha256sums=('a9dbee323351d109b7aee074a9cb89ca3e7bcf8ad8edef1851f4cf359bd50843')
_architectures="i686-w64-mingw32 x86_64-w64-mingw32"
build() {
cd "${srcdir}"
for _arch in ${_architectures}; do
mkdir -p "${_pkgsrc}/build-${_arch}"
${_arch}-meson "${_pkgsrc}" "${_pkgsrc}/build-${_arch}" \
-D maintainer-mode=true \
-D build-documentation=false \
-D validation=false \
-D build-pdf=false \
-D build-examples=false \
-D build-tests=false \
-D benchmark=false
meson compile -C "${_pkgsrc}/build-${_arch}"
done
}
package() {
cd "${srcdir}"
for _arch in ${_architectures}; do
meson install -C "${_pkgsrc}/build-${_arch}" --destdir "${pkgdir}"
find "${pkgdir}/usr/${_arch}" -name '*.exe' -exec "${_arch}-strip" "{}" \;
find "${pkgdir}/usr/${_arch}" -name '*.dll' -exec "${_arch}-strip" --strip-unneeded "{}" \;
find "${pkgdir}/usr/${_arch}" \( -name '*.a' -o -name '*.dll' \) -exec "${_arch}-strip" -g '{}' ';'
done
}
# vim: ts=2 sw=2 et:
|