blob: 53cf7b55143bb5907078177a37d7405645b69687 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
|
# Maintainer: drakkan <nicola.murino at gmail dot com>
pkgname=mingw-w64-meson
pkgver=1
pkgrel=21
arch=('any')
pkgdesc="Meson wrapper for MinGW (mingw-w64)"
depends=('meson' 'mingw-w64-gcc' 'mingw-w64-pkg-config')
makedepends=('mingw-w64-environment')
optdepends=('mingw-w64-wine: Set NEED_WINE env variable in your PKGBUILD to use wine support in meson'
'mingw-w64-cmake')
license=("GPL")
url="http://fedoraproject.org/wiki/MinGW"
source=("toolchain_generator.py"
"meson-mingw-wrapper")
sha256sums=('20b0c2add1182f2b8cdf53dea7c6fd870989a39abd7713acbce924cde716a85b'
'962db9754b149b89ec329dbc5e76f863725618bb60747f91906e2e5533e1be8c')
_architectures="i686-w64-mingw32 x86_64-w64-mingw32"
build() {
for _arch in ${_architectures}; do
unset CPPFLAGS
unset CFLAGS
unset CXXFLAGS
unset LDFLAGS
source mingw-env ${_arch}
python toolchain_generator.py --arch ${_arch} --output-file toolchain-${_arch}.meson
python toolchain_generator.py --arch ${_arch} --output-file toolchain-${_arch}-wine.meson --need-exe-wrapper
sed "s|@TRIPLE@|${_arch}|g;" meson-mingw-wrapper > ${_arch}-meson
done
}
package() {
install -d "${pkgdir}"/usr/bin
install -d "${pkgdir}"/usr/share/mingw
install -m 755 "${srcdir}/toolchain_generator.py" "$pkgdir/usr/bin/meson-cross-file-generator"
for _arch in ${_architectures}; do
install -m 755 "${srcdir}/${_arch}-meson" "$pkgdir/usr/bin/${_arch}-meson"
install -m 644 toolchain-${_arch}.meson "${pkgdir}"/usr/share/mingw/
install -m 644 toolchain-${_arch}-wine.meson "${pkgdir}"/usr/share/mingw/
done
}
# vim: ts=2 sw=2 et:
|