blob: b245768c9bde6c5818399ac84f4879644dca151d (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
|
pkgname=mingw-w64-openexr
pkgver=2.2.0
pkgrel=2
pkgdesc="An high dynamic-range image file format library (mingw-w64)"
url="http://www.openexr.com/"
arch=(any)
license=('BSD')
depends=('mingw-w64-crt' 'mingw-w64-zlib' 'mingw-w64-ilmbase')
makedepends=('mingw-w64-cmake' 'wine')
options=('staticlibs' '!buildflags' '!strip')
source=("http://download.savannah.gnu.org/releases/openexr/openexr-${pkgver}.tar.gz"
openexr-2.1.0_aligned-malloc.patch
openexr-2.1.0_cast.patch)
md5sums=('b64e931c82aa3790329c21418373db4e'
SKIP
SKIP)
_architectures="i686-w64-mingw32 x86_64-w64-mingw32"
prepare() {
cd "${srcdir}/openexr-${pkgver}"
# fedora patches
patch -p1 -i "${srcdir}"/openexr-2.1.0_aligned-malloc.patch
patch -p1 -i "${srcdir}"/openexr-2.1.0_cast.patch
# https://github.com/openexr/openexr/pull/159
sed -i "s|COMMAND \${CMAKE_CURRENT_BINARY_DIR}/\${CMAKE_CFG_INTDIR}/b44ExpLogTable >|COMMAND wine \${CMAKE_CURRENT_BINARY_DIR}/\${CMAKE_CFG_INTDIR}/b44ExpLogTable.exe >|g" IlmImf/CMakeLists.txt
sed -i "s|COMMAND \${CMAKE_CURRENT_BINARY_DIR}/\${CMAKE_CFG_INTDIR}/dwaLookups >|COMMAND wine \${CMAKE_CURRENT_BINARY_DIR}/\${CMAKE_CFG_INTDIR}/dwaLookups.exe >|g" IlmImf/CMakeLists.txt
sed -i "/ADD_SUBDIRECTORY ( IlmImfTest )/d" CMakeLists.txt
sed -i "/ADD_SUBDIRECTORY ( IlmImfUtilTest )/d" CMakeLists.txt
sed -i "/ADD_SUBDIRECTORY ( IlmImfFuzzTest )/d" CMakeLists.txt
sed -i "/ADD_SUBDIRECTORY ( exr/d" CMakeLists.txt # binaries/utilities
}
build() {
cd "${srcdir}/openexr-${pkgver}"
for _arch in ${_architectures}; do
mkdir -p build-${_arch} && pushd build-${_arch}
${_arch}-cmake -DNAMESPACE_VERSIONING=OFF -DILMBASE_PACKAGE_PREFIX=/usr/${_arch} ..
cp /usr/${_arch}/bin/*.dll IlmImf
make
popd
done
}
package() {
for _arch in ${_architectures}; do
cd "${srcdir}/openexr-${pkgver}/build-${_arch}"
make DESTDIR="${pkgdir}" install
install -d "$pkgdir"/usr/${_arch}/bin
mv "$pkgdir"/usr/${_arch}/lib/*.dll "$pkgdir"/usr/${_arch}/bin
rm -r "$pkgdir"/usr/${_arch}/share
${_arch}-strip --strip-unneeded "$pkgdir"/usr/${_arch}/bin/*.dll
${_arch}-strip -g "$pkgdir"/usr/${_arch}/lib/*.a
done
}
|