blob: 45eb3ecb463a492b52c2cebf2d2b28270e9ac8c0 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
|
pkgname=mingw-w64-openjpeg2
pkgver=2.1.2
pkgrel=3
arch=(any)
pkgdesc="An open source JPEG 2000 codec, version ${pkgver} (mingw-w64)"
license=("custom: BSD")
depends=(mingw-w64-libpng mingw-w64-lcms2)
makedepends=(mingw-w64-cmake)
options=(staticlibs !strip !buildflags)
url="https://www.openjpeg.org"
source=("https://github.com/uclouvain/openjpeg/archive/v$pkgver.tar.gz"
"0001-fix-install-for-dlls.all.patch"
"0003-versioned-dlls.mingw.patch"
"0005-sock-jpip.all.patch"
"repair_bugs_of_871_and_872.patch")
sha256sums=('4ce77b6ef538ef090d9bde1d5eeff8b3069ab56c4906f083475517c2c023dfa7'
'3f3bde353ca3432f157258164c5e3c345af82ca3a9d5a68f815c3030b01cbc32'
'a221300d278f1a57b1ea5c70314702cd4234a2560ed2335bd5940fd921e78eda'
'b7b22dca26d5fd98ca5bc6ce775bbbabebc0e10fcf07fd0afb54d580699b8312'
'e352e9480925a31804d965c673545eeaa32d0a47605abaaa09b515ca956058ba')
_architectures="i686-w64-mingw32 x86_64-w64-mingw32"
prepare() {
cd openjpeg-$pkgver
patch -p1 -i ${srcdir}/0001-fix-install-for-dlls.all.patch
patch -p1 -i ${srcdir}/0003-versioned-dlls.mingw.patch
patch -p1 -i ${srcdir}/0005-sock-jpip.all.patch
patch -Np1 -i ../repair_bugs_of_871_and_872.patch
}
build() {
cd openjpeg-$pkgver
for _arch in ${_architectures}; do
unset LDFLAGS
mkdir "build-${_arch}-static" && pushd "build-${_arch}-static"
${_arch}-cmake \
-DCMAKE_BUILD_TYPE=Release \
-DBUILD_DOC=OFF \
-DBUILD_TESTING=OFF \
-DBUILD_SHARED_LIBS=OFF \
..
make
popd
mkdir "build-${_arch}-shared" && pushd "build-${_arch}-shared"
${_arch}-cmake \
-DCMAKE_BUILD_TYPE=Release \
-DBUILD_DOC=OFF \
-DBUILD_TESTING=OFF \
-DBUILD_PKGCONFIG_FILES=ON \
..
make
popd
done
}
package() {
for _arch in ${_architectures}; do
cd "${srcdir}/openjpeg-$pkgver/build-${_arch}-static"
make DESTDIR="$pkgdir" install
cd "${srcdir}/openjpeg-$pkgver/build-${_arch}-shared"
make DESTDIR="$pkgdir" install
find "$pkgdir/usr/${_arch}" -name '*.exe' -exec ${_arch}-strip {} \;
find "$pkgdir/usr/${_arch}" -name '*.dll' -exec ${_arch}-strip --strip-unneeded {} \;
find "$pkgdir/usr/${_arch}" -name '*.a' -o -name '*.dll' | xargs ${_arch}-strip -g
find "$pkgdir/usr/${_arch}/lib" -name '*.dll' -exec mv {} "$pkgdir/usr/${_arch}/bin" \;
done
}
|