blob: 0674751b15e587bf373741d0ee9fd5b31721a621 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
|
# Maintainer: pingplug <pingplug@foxmail.com>
# Contributor: xantares <xantares09@hotmail.com>
_commit=3dd5810143e51dabdc58069e55b09a950349fa08 # tags/0.23.12^0
_architectures="i686-w64-mingw32 x86_64-w64-mingw32"
pkgname=mingw-w64-p11-kit
pkgver=0.23.12
pkgrel=1
pkgdesc="Provides a way to load and enumerate PKCS#11 modules (mingw-w64)"
arch=('any')
url="https://p11-glue.freedesktop.org"
license=('BSD')
depends=('mingw-w64-crt'
'mingw-w64-libtasn1'
'mingw-w64-libffi')
makedepends=('mingw-w64-configure'
'git')
options=('!strip' 'staticlibs' '!buildflags')
source=("git+https://github.com/p11-glue/p11-kit#commit=${_commit}"
"0001-Build-and-install-libnssckbi-p11-kit.so.patch")
sha256sums=('SKIP'
'0736f74cec5ca49d91afa47cd84f9ac0404947bf0064358e22c3e53b69e82798')
pkgver() {
cd "${srcdir}"/p11-kit
git describe --tags | sed 's/-/+/g'
}
prepare() {
cd "${srcdir}"/p11-kit
# Build and install an additional library (libnssckbi-p11-kit.so) which
# is a copy of p11-kit-trust.so but uses the same label for root certs as
# libnssckbi.so ("Builtin Object Token" instead of "Default Trust")
# https://bugs.freedesktop.org/show_bug.cgi?id=66161
patch -Np1 -i ../0001-Build-and-install-libnssckbi-p11-kit.so.patch
NOCONFIGURE=1 ./autogen.sh
}
build() {
cd "${srcdir}"/p11-kit
for _arch in ${_architectures}; do
mkdir -p build-${_arch} && pushd build-${_arch}
${_arch}-configure --disable-static --disable-silent-rules --disable-trust-module
make
popd
done
}
package() {
for _arch in ${_architectures}; do
cd "${srcdir}"/p11-kit/build-${_arch}
make install DESTDIR="${pkgdir}"
rm "${pkgdir}"/usr/${_arch}/bin/*.exe
rm -r "${pkgdir}"/usr/${_arch}/libexec
rm -r "${pkgdir}"/usr/${_arch}/etc
${_arch}-strip --strip-unneeded "${pkgdir}"/usr/${_arch}/bin/*.dll
${_arch}-strip -g "${pkgdir}"/usr/${_arch}/lib/*.a
done
}
# vim:set ts=2 sw=2 et:
|