blob: 79551562816e9d90f6a6339d8252eb13311c59ac (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
|
# Maintainer: pingplug <pingplug@foxmail.com>
# Contributor: Schala Zeal <schalaalexiazeal@gmail.com>
_commit=5d46e21df66a11233186ddf27ca8c70149307871 # after a bug fix
_architectures="i686-w64-mingw32 x86_64-w64-mingw32"
pkgname=mingw-w64-pango
pkgver=1.42.1+4+g5d46e21d
pkgrel=3
pkgdesc="A library for layout and rendering of text (mingw-w64)"
arch=('any')
url="http://www.pango.org"
license=('LGPL')
depends=('mingw-w64-harfbuzz'
'mingw-w64-fribidi'
'mingw-w64-fontconfig'
'mingw-w64-freetype2'
'mingw-w64-cairo')
optdepends=('mingw-w64-libthai: libthai support')
makedepends=('gtk-doc'
'gobject-introspection'
'mingw-w64-meson'
'mingw-w64-wine'
'git')
options=('!strip' 'staticlibs' '!buildflags')
source=("git+https://gitlab.gnome.org/GNOME/pango.git#commit=${_commit}")
sha256sums=('SKIP')
pkgver() {
cd "${srcdir}/pango"
git describe --tags | sed 's/-/+/g'
}
prepare() {
cd "${srcdir}/pango"
}
build() {
export NEED_WINE=1
cd "${srcdir}/pango"
for _arch in ${_architectures}; do
mkdir -p build-${_arch} && pushd build-${_arch}
${_arch}-meson \
--buildtype=release \
--default-library=both \
-D 'enable_docs=false' \
-D 'gir=false' \
..
ninja
popd
done
}
package() {
export NEED_WINE=1
for _arch in ${_architectures}; do
cd "${srcdir}/pango/build-${_arch}"
DESTDIR="${pkgdir}" ninja install
rm -r "${pkgdir}/usr/${_arch}/lib/installed-tests"
rm -r "${pkgdir}/usr/${_arch}/share"
find "${pkgdir}/usr/${_arch}" -name '*.exe' -exec ${_arch}-strip {} \;
find "${pkgdir}/usr/${_arch}" -name '*.dll' -exec ${_arch}-strip --strip-unneeded {} \;
find "${pkgdir}/usr/${_arch}" -name '*.a' -o -name '*.dll' | xargs ${_arch}-strip -g
done
}
# vim:set ts=2 sw=2 et:
|