blob: 975d0625d39409da78437d54b42199cf61992458 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
|
pkgname=mingw-w64-paraview
_majordotminor=5.5
pkgver=${_majordotminor}.0
_pkgver=${pkgver}
pkgrel=1
pkgdesc='Parallel Visualization Application using VTK (mingw-w64)'
arch=('any')
url='http://www.paraview.org'
license=('custom')
depends=('mingw-w64-qt5-xmlpatterns' 'mingw-w64-qt5-tools' 'mingw-w64-boost' 'mingw-w64-glew' 'mingw-w64-expat' 'mingw-w64-freetype2' 'mingw-w64-libjpeg' 'mingw-w64-libxml2' 'mingw-w64-libtheora' 'mingw-w64-libpng' 'mingw-w64-libtiff' 'mingw-w64-zlib' 'mingw-w64-jsoncpp' 'mingw-w64-pugixml' 'mingw-w64-hdf5' 'mingw-w64-lz4' 'mingw-w64-cgns' 'mingw-w64-netcdf-cxx-legacy')
makedepends=('mingw-w64-cmake' 'mingw-w64-eigen' 'wine')
options=('!buildflags' '!strip' 'staticlibs')
source=("http://paraview.org/files/v${_majordotminor}/ParaView-v${_pkgver}.tar.gz"
"vtk-fix-jsoncpp-module.patch")
sha256sums=('1b619e326ff574de808732ca9a7447e4cd14e94ae6568f55b6581896cd569dff'
'86af85dddde9d02877d6eda60c440db3ae903e525238d4dc19be7a25a92597f7')
_architectures="i686-w64-mingw32 x86_64-w64-mingw32"
prepare() {
cd "${srcdir}/ParaView-v${_pkgver}"
# cannot be modified upstream, see https://gitlab.kitware.com/paraview/paraview/merge_requests/1716
sed -i "s|IF(NOT CMAKE_CROSSCOMPILING)|IF(NOT PARAVIEW_COMPILE_TOOLS_IMPORTED)|g" ThirdParty/protobuf/vtkprotobuf/src/CMakeLists.txt
# https://gitlab.kitware.com/vtk/vtk/merge_requests/4017
sed -i "s|GetLibraryPathForSymbolWin32(\&function)|GetLibraryPathForSymbolWin32(reinterpret_cast<const void*>(\&function))|g" VTK/Common/Misc/vtkResourceFileLocator.h
# https://gitlab.kitware.com/vtk/vtk/merge_requests/4107
patch -p1 -i "${srcdir}/vtk-fix-jsoncpp-module.patch"
}
build() {
cd "${srcdir}/ParaView-v${_pkgver}"
for _arch in ${_architectures}; do
mkdir -p build-${_arch} && pushd build-${_arch}
${_arch}-cmake \
-DPARAVIEW_INSTALL_DEVELOPMENT_FILES:BOOL=ON \
-DPARAVIEW_ENABLE_FFMPEG:BOOL=OFF \
-DPARAVIEW_ENABLE_PYTHON:BOOL=OFF \
-DPARAVIEW_PYTHON_VERSION=2 \
-DPARAVIEW_ENABLE_EMBEDDED_DOCUMENTATION=OFF \
-DPARAVIEW_QT_VERSION=5 \
-DPARAVIEW_USE_VISITBRIDGE:BOOL=OFF \
-DPARAVIEW_USE_OSPRAY:BOOL=OFF \
-DVTK_USE_SYSTEM_LIBRARIES=ON \
-DVTK_USE_SYSTEM_QTTESTING=OFF \
-DVTK_USE_SYSTEM_XDMF2=OFF \
-DVTK_USE_SYSTEM_PROTOBUF:BOOL=OFF \
-DVTK_USE_SYSTEM_GL2PS=OFF \
-DVTK_USE_SYSTEM_LIBHARU=OFF \
-DVTK_PYTHON_VERSION=2 \
-DVTK_QT_VERSION=5 \
-DVTK_RENDERING_BACKEND:STRING=OpenGL2 \
-DVTK_SMP_IMPLEMENTATION_TYPE:STRING=OpenMP \
-DHDF5_ROOT=/usr/${_arch}/ ..
make
popd
done
}
package() {
for _arch in ${_architectures}; do
cd "$srcdir"/ParaView-v${_pkgver}/build-${_arch}
make install/fast DESTDIR="$pkgdir"
rm -r "$pkgdir"/usr/${_arch}/share
${_arch}-strip --strip-unneeded "$pkgdir"/usr/${_arch}/bin/*.dll
${_arch}-strip -g "$pkgdir"/usr/${_arch}/lib/*.a
done
}
|