blob: f8b354250cd9bb58cff52aefd6838c5f15148ec8 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
|
# Maintainer: ant32 <antreimer@gmail.com>
_qt_module=qtactiveqt
pkgname=mingw-w64-qt5-activeqt
pkgver=5.5.0
pkgrel=1
arch=(any)
pkgdesc="Qt's ActiveX Framework (mingw-w64)"
depends=(mingw-w64-qt5-base)
makedepends=(mingw-w64-{gcc,headers-git,crt-git,winpthreads-git} python)
options=(!strip !buildflags staticlibs)
groups=(mingw-w64-qt mingw-w64-qt5)
license=("custom, FDL, GPL3, LGPL")
url="http://qt-project.org"
_pkgfqn="${_qt_module}-opensource-src-${pkgver}"
source=("http://download.qt-project.org/official_releases/qt/5.5/${pkgver}/submodules/${_pkgfqn}.tar.xz"
"qt5-activeqt-fix-compilation.patch"
"qtactiveqt-fix-build.patch"
"qtactiveqt-win64.patch")
md5sums=('be5e0a79decc87d02c574348d9663e6a'
'86c63b9808b0c8c7a8c2203bee73c42b'
'7a7ba436452aa56613b3fbb15684e094'
'1264d0274586aec14f96a978b416b048')
_architectures="i686-w64-mingw32 x86_64-w64-mingw32"
prepare() {
cd "${srcdir}/${_pkgfqn}"
# Fix linker error:
# qaxserverbase.cpp:1769: undefined reference to `qt_sendSpontaneousEvent(QObject*, QEvent*)'
patch -p0 -i ../qt5-activeqt-fix-compilation.patch
# Don't try to build stuff which requires windows.h with the native Linux gcc
patch -p1 -i ../qtactiveqt-fix-build.patch
# dumpcpp and MetaObjectGenerator::readClassInfo do not handle win64
# https://bugreports.qt.io/browse/QTBUG-46827
patch -p1 -i ../qtactiveqt-win64.patch
}
build() {
cd "${srcdir}/${_pkgfqn}"
for _arch in ${_architectures}; do
mkdir -p build-${_arch} && pushd build-${_arch}
${_arch}-qmake-qt5 ../${_qt_module}.pro
make
popd
done
}
package() {
cd "${srcdir}/${_pkgfqn}"
for _arch in ${_architectures}; do
pushd build-${_arch}
make INSTALL_ROOT="$pkgdir" install
# The .dll's are installed in both bindir and libdir
# One copy of the .dll's is sufficient
rm -f "${pkgdir}/usr/${_arch}/lib/"*.dll
find "${pkgdir}/usr/${_arch}" -name "*.exe" -o -name "*.bat" -o -name "*.def" -o -name "*.exp" -o -name '*.prl' | xargs -rtl1 rm
find "${pkgdir}/usr/${_arch}" -name "*.dll" -exec ${_arch}-strip --strip-unneeded {} \;
find "${pkgdir}/usr/${_arch}" -name "*.a" -o -name "*.dll" | xargs -rtl1 ${_arch}-strip -g
popd
done
}
|