blob: 4f9099302f96ed98e2ba839de6fbfca7b3d6a18c (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
|
# Maintainer: Martchus <martchus@gmx.net>
# Contributor: ant32 <antreimer@gmail.com>
# All my PKGBUILDs are managed at https://github.com/Martchus/PKGBUILDs where
# you also find the URL of a binary repository.
# Includes dynamic and static versions; if only one version is requried, just
# set $NO_STATIC_LIBS or $NO_SHARED_LIBS.
_qt_module=qtlocation
pkgname=mingw-w64-qt5-location
pkgver=5.9.1
pkgrel=1
arch=('any')
pkgdesc='Provides access to position, satellite and area monitoring classes (mingw-w64)'
depends=('mingw-w64-qt5-base' 'mingw-w64-qt5-declarative')
makedepends=('mingw-w64-gcc' 'mingw-w64-pkg-config' 'mingw-w64-angleproject')
optdepends=('mingw-w64-angleproject: Mapbox GL plugin')
options=('!strip' '!buildflags' 'staticlibs')
groups=('mingw-w64-qt5')
license=('GPL3' 'LGPL' 'FDL' 'custom')
url='https://www.qt.io/'
_pkgfqn="${_qt_module}-opensource-src-${pkgver}"
source=("https://download.qt.io/official_releases/qt/${pkgver:0:3}/${pkgver}/submodules/${_pkgfqn}.tar.xz"
'0001-Ensure-static-3rdparty-libs-are-linked-correctly.patch'
'0002-Enforce-use-of-ANGLE-in-Mapbox-GL-plugin.patch')
sha256sums=('4bc43c1df69c5322f982588711d4a65f8408b71a36e43ba19b39d1aae87e1515'
'a25cb16e76921eb7f5a6d36f420d797716516036338bc3df8773fdd8525e0baa'
'ee4c4d8ede233cfe470dad61523b4474baafb234fe498e5e5a92d4fee7c4247b')
_architectures='i686-w64-mingw32 x86_64-w64-mingw32'
[[ $NO_STATIC_LIBS ]] || \
makedepends+=('mingw-w64-qt5-base-static') \
optdepends+=('mingw-w64-qt5-base-static: use of static libraries') \
_configurations+=('CONFIG+=static')
[[ $NO_SHARED_LIBS ]] || \
_configurations+=('CONFIG+=actually_a_shared_build CONFIG+=shared')
prepare() {
cd "${srcdir}/${_pkgfqn}"
# Apply patches; further descriptions can be found in patch files itself
for patch in "$srcdir/"*.patch; do
patch -p1 -i "$patch"
done
}
build() {
cd "${srcdir}/${_pkgfqn}"
for _arch in ${_architectures}; do
for _config in "${_configurations[@]}"; do
msg2 "Building ${_config##*=} version for ${_arch}"
mkdir -p build-${_arch}-${_config##*=} && pushd build-${_arch}-${_config##*=}
${_arch}-qmake-qt5 ../${_qt_module}.pro ${_config}
make
popd
done
done
}
package() {
cd "${srcdir}/${_pkgfqn}"
for _arch in ${_architectures}; do
for _config in "${_configurations[@]}"; do
pushd build-${_arch}-${_config##*=}
make INSTALL_ROOT="$pkgdir" install
find "${pkgdir}/usr/${_arch}/lib" -maxdepth 1 -name "*.dll" -exec rm {} \;
[ "$NO_STATIC_EXECUTABLES" -a "${_config##*=}" = static -o "$NO_EXECUTABLES" ] && \
find "${pkgdir}/usr/${_arch}" -name "*.exe" -exec rm {} \; || \
find "${pkgdir}/usr/${_arch}" -name "*.exe" -exec ${_arch}-strip --strip-all {} \;
find "${pkgdir}/usr/${_arch}" -name "*.dll" -exec ${_arch}-strip --strip-unneeded {} \;
find "${pkgdir}/usr/${_arch}" -name "*.a" -exec ${_arch}-strip -g {} \;
[[ -d "${pkgdir}/usr/${_arch}/lib/qt/bin/" ]] && \
find "${pkgdir}/usr/${_arch}/lib/qt/bin/" -exec strip --strip-all {} \;
find "${pkgdir}/usr/${_arch}/lib/" -iname "*.so.$pkgver" -exec strip --strip-unneeded {} \;
popd
done
done
}
|