blob: 7acb0f7aeb2d55d79701157c5ee2e00bf252f8b7 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
|
# Maintainer: pingplug < aur at pingplug dot me >
# Contributor: Filip Brcic < brcha at gna dot org >
# Thanks to the patch from the MXE project <mxe.cc>
_basever=8.1
_patchlevel=000
_architectures="i686-w64-mingw32 x86_64-w64-mingw32"
pkgname=mingw-w64-readline
pkgver=${_basever}.${_patchlevel}
pkgrel=2
pkgdesc="GNU readline library (mingw-w64)"
arch=('any')
url="https://tiswww.case.edu/php/chet/readline/rltop.html"
license=('GPL')
depends=('mingw-w64-crt'
'mingw-w64-pdcurses'
'mingw-w64-termcap')
makedepends=('mingw-w64-configure')
options=('!strip' 'staticlibs' '!buildflags')
source=("https://ftp.gnu.org/gnu/readline/readline-${_basever}.tar.gz"{,.sig}
fix_signal.diff)
if [ ${_patchlevel} -gt 00 ]; then
for (( _p=1; _p<=$((10#${_patchlevel})); _p++ )); do
source=(${source[@]} "https://ftp.gnu.org/gnu/readline/readline-${_basever}-patches/readline${_basever//./}-$(printf "%03d" ${_p})"{,.sig})
done
fi
sha256sums=('f8ceb4ee131e3232226a17f51b164afc46cd0b9e6cef344be87c65962cb82b02'
'SKIP'
'277ee9b021cb0d91c1079736ce8c3a8b7afd116cb5735866a044b6e82a4cdd21')
validpgpkeys=(7C0135FB088AAF6C66C650B9BB5869F064EA74AB) # Chet Ramey <chet@cwru.edu>
prepare() {
cd "${srcdir}/readline-${_basever}"
for (( _p=1; _p<=$((10#${_patchlevel})); _p++ )); do
msg "applying patch readline${_basever//./}-$(printf "%03d" ${_p})"
patch -Np0 -i ${srcdir}/readline${_basever//./}-$(printf "%03d" ${_p})
done
# Remove RPATH from shared objects (FS#14366)
sed -i 's|-Wl,-rpath,$(libdir) ||g' support/shobj-conf
patch -Np1 -i ../fix_signal.diff
}
build() {
cd "${srcdir}/readline-${_basever}"
for _arch in ${_architectures}; do
mkdir -p build-${_arch} && pushd build-${_arch}
bash_cv_wcwidth_broken=no ${_arch}-configure \
--target=${_arch} \
--enable-multibyte \
--without-purify \
--with-curses
make SHLIB_LIBS="-lpdcurses -ltermcap"
popd
done
}
package() {
for _arch in ${_architectures} ; do
cd "${srcdir}/readline-${_basever}/build-${_arch}"
make install DESTDIR="${pkgdir}" SHLIB_LIBS="-lpdcurses -ltermcap"
rm -r "${pkgdir}"/usr/${_arch}/share/
${_arch}-strip --strip-unneeded "${pkgdir}"/usr/${_arch}/bin/*.dll
${_arch}-strip --strip-debug "${pkgdir}"/usr/${_arch}/lib/*.a
done
}
# vim:set ts=2 sw=2 et:
|